;================================================================================
; Robert Johnstone
; Simon Fraser University
;
; Copyright 2000,2002 Robert W. Johnstone
;--------------------------------------------------------------------------------

; 2002/06/03
; - modified code becase interface to dbCreateMumpsPin changed
; 2000/07/01
; - created

if( (!boundp( 'admLibraryName )) then
	warn( "Setting the destination library to default value of ADM" )
	admLibraryName = "ADM"
)

pcDefinePCell(
	list( ddGetObj(admLibraryName) "resistor" "layout"
	) ; end of list for first argument

	(
		( length		100.0 )
		( pin_size		20.0 )
		( chamfer		0.0 )
		( include_R		t )
	) ; end of parameter list

	prog( 
		let( pcNet tmp tmp2 pcTechFile )

		; load tech file rules
		pcTechFile = techGetTechFile( pcCellView )
		p0_minWidth = techGetSpacingRule( pcTechFile "minWidth" "POLY0" )
		if( (p0_minWidth==nil) then warn("minWidth rule for POLY0 not set") )
		p1_nomSpacing = techGetSpacingRule( pcTechFile "nomSpacing" "POLY1" )
		if( (p1_nomSpacing==nil) then warn("nomSpacing rule for POLY1 not set") )
		p1a1_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY1" "ANCHOR1" )
		if( (p1a1_enclosure==nil) then warn("minEnclosure rule for POLY1->ANCHOR1 not set") )
		p1p2_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY1" "POLY2" )
		if( (p1p2_enclosure==nil) then warn("minEnclosure rule for POLY1->POLY2 not set") )
		p2m_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY2" "METAL" )
		if( (p2m_enclosure==nil) then warn("minEnclosure rule for POLY2->METAL not set") )
		p2v_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY2" "P1P2VIA" )
		if( (p2v_enclosure==nil) then warn("minEnclosure rule for POLY2->P1P2VIA not set") )
		v_nomWidth = techGetSpacingRule( pcTechFile "nomWidth" "P1P2VIA" )
		if( (v_nomWidth==nil) then warn("nomWidth rule for P1P2VIA not set") )
		m_nomWidth = techGetSpacingRule( pcTechFile "nomWidth" "METAL" )
		if( (m_nomWidth==nil) then warn("nomWidth rule for METAL not set") )

		; check parameters
		length = if( (length<p1_nomSpacing) p1_nomSpacing length )
		pin_size = if( (pin_size<v_nomWidth+2*p2v_enclosure+2*p1p2_enclosure) v_nomWidth+2*p2v_enclosure+2*p1p2_enclosure pin_size )
		pin_size = if( (pin_size<m_nomWidth+2*p2m_enclosure+2*p1p2_enclosure) m_nomWidth+2*p2m_enclosure+2*p1p2_enclosure pin_size )
		chamfer = if( (chamfer<0) 0 chamfer )

		; create terminals
		tmp = (length + pin_size) * 0.5
		pcNet = dbMakeNet( pcCellView "R1" )
		dbCreateMumpsPin( pcCellView pcNet -tmp:0 pin_size chamfer )
		pcNet = dbMakeNet( pcCellView "R2" )
		dbCreateMumpsPin( pcCellView pcNet tmp:0 pin_size chamfer )

		; create POLY0 resistor
		tmp = length*0.5 + pin_size * 0.5
		dbCreateRect( pcCellView "POLY0" list( -tmp:-p0_minWidth*0.5 tmp:p0_minWidth*0.5 ) )

		; create resistance label
		if( (include_R==t) then
			tmp = 1.3e-5 * length * 1e-6 / ( 0.5e-6 * p0_minWidth*1e-6 )
			dbCreateLabel( pcCellView '("TMP" "drawing") 0:0 sprintf(nil "R = %0.0f" tmp) "centerCenter" "R0" "stick" pin_size*0.5 )
		)
		

		; add stretch handles
		rodObj = rodGetObj( "" pcCellView )
		rodAssignHandleToParameter(
			?parameter	"length"
			?rodObj		rodObj
			?handleName	list( "centerLeft" "centerRight" )
			?displayName	"length"
			?stretchDir	"x"
			?userFunction	lambda( (SPCInfo) SPCInfo->paramVal + 2*SPCInfo->increment )
		)

		; Create the instNamePrefix property
		dbReplaceProp( pcCellView "instNamePrefix" "string" "resistor" )
		; set version string
		dbReplaceProp( pcCellView "version" "string" "1.2.2" )
		; body SKILL code returns value t
		return(t)

	) ; end of body-of-SKILL-code prog

) ; ; end of pcDefinePCell