;================================================================================
; Robert Johnstone
; Simon Fraser University
;
; Copyright 2000,2002 Robert W. Johnstone
;--------------------------------------------------------------------------------

; 2002/06/03
; - modified code because the interface to dbCreateMumpsPin changed
; 2000/07/01
; - created cell

if( (!boundp( 'admLibraryName )) then
	warn( "Setting the destination library to default value of ADM" )
	admLibraryName = "ADM"
)

pcDefinePCell(
	list( ddGetObj(admLibraryName) "resistor_snake" "layout"
	) ; end of list for first argument

	(
		( width			100.0 )
		( bars			5 )
		( gap			0 )
		( pin_size		20.0 )
		( chamfer		0.0 )
		( include_R		t )
	) ; end of parameter list

	prog( 
		let( pcNet tmp tmp2 pcTechFile )

		; load tech file rules
		pcTechFile = techGetTechFile( pcCellView )
		p0_minWidth = techGetSpacingRule( pcTechFile "minWidth" "POLY0" )
		if( (p0_minWidth==nil) then warn("minWidth rule for POLY0 not set") )
		p0_minSpacing = techGetSpacingRule( pcTechFile "minSpacing" "POLY0" )
		if( (p0_minSpacing==nil) then warn("minSpacing rule for POLY0 not set") )
		p1a1_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY1" "ANCHOR1" )
		if( (p1a1_enclosure==nil) then warn("minEnclosure rule for POLY1->ANCHOR1 not set") )
		p1p2_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY1" "POLY2" )
		if( (p1p2_enclosure==nil) then warn("minEnclosure rule for POLY1->POLY2 not set") )
		p2m_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY2" "METAL" )
		if( (p2m_enclosure==nil) then warn("minEnclosure rule for POLY2->METAL not set") )
		p2v_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY2" "P1P2VIA" )
		if( (p2v_enclosure==nil) then warn("minEnclosure rule for POLY2->P1P2VIA not set") )
		v_minWidth = techGetSpacingRule( pcTechFile "minWidth" "P1P2VIA" )
		if( (v_minWidth==nil) then warn("minWidth rule for P1P2VIA not set") )
		m_minWidth = techGetSpacingRule( pcTechFile "minWidth" "METAL" )
		if( (m_minWidth==nil) then warn("minWidth rule for METAL not set") )

		; check parameters
		width = if( (width<2*p0_minWidth+2*p0_minSpacing) 2*p0_minWidth+2*p0_minSpacing width )
		bars = if( (bars<0) 0 bars )
		gap = if( (gap<p0_minSpacing) p0_minSpacing gap )
		pin_size = if( (pin_size<v_minWidth+2*p2v_enclosure+2*p1p2_enclosure) v_minWidth+2*p2v_enclosure+2*p1p2_enclosure pin_size )
		pin_size = if( (pin_size<m_minWidth+2*p2m_enclosure+2*p1p2_enclosure) m_minWidth+2*p2m_enclosure+2*p1p2_enclosure pin_size )
		chamfer = if( (chamfer<0) 0 chamfer )

		; create first half-bar
		origin_x = -( (bars + 2) * (p0_minWidth + gap) + gap ) * 0.5
		path = list( origin_x+gap+p0_minWidth*0.5:width*0.5-p0_minWidth*0.5 origin_x+gap+p0_minWidth*0.5:0 origin_x-pin_size*0.5:0 )

		; create bars
		for( lp 1 bars
			x = origin_x + (lp+1) * (p0_minWidth + gap) - p0_minWidth*0.5

			if( ( mod(lp,2) == 0 ) then
				path = cons( x:-width*0.5+p0_minWidth*0.5 path )
				path = cons( x:width*0.5-p0_minWidth*0.5 path )
			else
				path = cons( x:width*0.5-p0_minWidth*0.5 path )
				path = cons( x:-width*0.5+p0_minWidth*0.5 path )
			)
		)

		; last half-bar
		x = origin_x + (bars + 2) * (p0_minWidth + gap) - p0_minWidth*0.5
		if( ( mod(bars,2) == 0 ) then
			path = cons( x:width*0.5-p0_minWidth*0.5 path )
		else	
			path = cons( x:-width*0.5+p0_minWidth*0.5 path )
		)
		path = cons( x:0 path )
		path = cons( x+p0_minWidth*0.5+gap+pin_size*0.5:0 path )
		pcShape = dbCreatePath( pcCellView "POLY0" path p0_minWidth )
		dbConvertPathToPolygon( pcShape )

		; create terminals
		tmp = origin_x - pin_size * 0.5
		pcNet = dbMakeNet( pcCellView "R1" )
		dbCreateMumpsPin( pcCellView pcNet -tmp:0 pin_size chamfer )
		pcNet = dbMakeNet( pcCellView "R2" )
		dbCreateMumpsPin( pcCellView pcNet tmp:0 pin_size chamfer )

		; create resistance label
		if( (include_R==t) then
			; length
			tmp = (bars+1) * (width-2*p0_minWidth) + (bars+3) * gap
			; corner
			tmp = tmp + (bars*2 + 4) * 0.6 * p0_minWidth
			; and calcuate the resistance
			tmp = 1.3e-5 * tmp * 1e-6 / ( 0.5e-6 * p0_minWidth*1e-6 )
			; and display the resistance
			dbCreateLabel( pcCellView '("TMP" "drawing") 0:0 sprintf(nil "R = %0.0f" tmp) "centerCenter" "R0" "stick" pin_size*0.5 )
		)
		
		; create stretch handles
		rodObj = rodGetObj( "" pcCellView )
		rodAssignHandleToParameter(
			?parameter	"width"
			?rodObj		rodObj
			?handleName	list( "upperCenter" "lowerCenter" )
			?displayName	"width"
			?stretchDir	"y"
			?userFunction	lambda( (SPCInfo) SPCInfo->paramVal + 2*SPCInfo->increment )
		)
		rodAssignHandleToParameter(
			?parameter	"bars"
			?rodObj		rodObj
			?handleName	list( "centerLeft" "centerRight" )
			?displayName	"bars"
			?stretchDir	"x"
			?updateIncrement	(p0_minWidth + gap)*0.5
			?userFunction	lambda( (SPCInfo) SPCInfo->paramVal + round(SPCInfo->increment/SPCInfo->userData) )
			?userData	p0_minWidth + gap
		)

		; Create the instNamePrefix property
		dbReplaceProp( pcCellView "instNamePrefix" "string" "resistor" )
		; set version string
		dbReplaceProp( pcCellView "version" "string" "1.0.1" )
		; body SKILL code returns value t
		return(t)

	) ; end of body-of-SKILL-code prog

) ; ; end of pcDefinePCell