;================================================================================
; Robert Johnstone
; Simon Fraser University
;
; Copyright 2000,2001,2002 Robert W. Johnstone
;--------------------------------------------------------------------------------

; 2002/02/21
; - modified code to use poly and anchor variables instead of hardcoded layers
; - added spring_2
; 2000/11/29
; - creation date

unless( boundp( 'admLibraryName )
	warn( "Setting the destination library to default value of ADM" )
	admLibraryName = "ADM"
)

pcDefinePCell(
	list( ddGetObj(admLibraryName) "spring" "layout"
	) ; end of list for first argument

	(
		( width			100.0 )
		( gap			2.0 )
		( bars			5 )
		( include_anchor	t )
		( include_poly0		"boolean"	nil )
	) ; end of parameter list

	prog( 
		; declare variables
		( pcTechFile pcShape rodObj
			p0p_enclosure p_minSpacing p_minWidth p_nomWidth pa_enclosure a_nomWidth 
			poly anchor
			y w2 path )
			
		; set layers
		poly = "POLY1"
		anchor = "ANCHOR1"

		; load tech file rules
		pcTechFile = techGetTechFile( pcCellView )
		p0p_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY0" poly )
		if( (p0p_enclosure==nil) then warn(strcat( "minEnclosure rule for POLY0->" poly " not set") ) )
		p_minSpacing = techGetSpacingRule( pcTechFile "minSpacing" poly )
		if( (p_minSpacing==nil) then warn(strcat( "minSpacing rule for " poly " not set") ) )
		p_minWidth = techGetSpacingRule( pcTechFile "minWidth" poly )
		if( (p_minWidth==nil) then warn(strcat( "minWidth rule for " poly " not set") ) )
		p_nomWidth = techGetSpacingRule( pcTechFile "nomWidth" poly )
		if( (p_nomWidth==nil) then warn(strcat( "nomWidth rule for " poly " not set") ) )
		pa_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" poly anchor )
		if( (pa_enclosure==nil) then warn(strcat( "minEnclosure rule for " poly "->" anchor " not set") ) )
		a_nomWidth = techGetSpacingRule( pcTechFile "nomWidth" anchor )
		if( (a_nomWidth==nil) then warn(strcat( "nomWidth rule for " anchor " not set") ) )

		; fix parameters
		gap = if( (gap<p_minSpacing) p_minSpacing gap )
		bars = if( (bars<0) 0 bars )

		; create first half-bar
		dbCreateRect( pcCellView "TMP" list( -p_minWidth*0.5:0 p_minWidth*0.5:-p_minWidth ) )
		path = list( width*0.5-p_minWidth*0.5:gap+p_minWidth*0.5 0:gap+p_minWidth*0.5 0:0 )

		; create bars
		for( lp 1 bars
			y = (lp+1) * (p_minWidth + gap) - p_minWidth*0.5

			if( ( mod(lp,2) == 0 ) then
				path = cons( -width*0.5+p_minWidth*0.5:y path )
				path = cons( width*0.5-p_minWidth*0.5:y path )
			else
				path = cons( width*0.5-p_minWidth*0.5:y path )
				path = cons( -width*0.5+p_minWidth*0.5:y path )
			)
		)

		; last half-bar
		y = (bars + 2) * (p_minWidth + gap) - p_minWidth*0.5
		if( ( mod(bars,2) == 0 ) then
			path = cons( width*0.5-p_minWidth*0.5:y path )
			path = cons( 0:y path )
		else	
			path = cons( -width*0.5+p_minWidth*0.5:y path )
			path = cons( 0:y path )
		)
		path = cons( 0:y+p_minWidth*0.5+gap path )
		pcShape = dbCreatePath( pcCellView poly path p_minWidth )
		dbConvertPathToPolygon( pcShape )
		
		; create anchor, or terminal
		y = (bars + 2) * (p_minWidth + gap)
		if( (include_anchor==t) then
			w2 = a_nomWidth + 2 * pa_enclosure
			dbCreateRect( pcCellView poly list( -w2*0.5:y+gap w2*0.5:y+gap+w2 ) )
			dbCreateRect( pcCellView anchor list( -a_nomWidth*0.5:y+gap+pa_enclosure a_nomWidth*0.5:y+gap+pa_enclosure+a_nomWidth ) )
			if( (include_poly0==t) then
				dbCreateRect( pcCellView "POLY0" list( -w2*0.5-p0p_enclosure:y+gap-p0p_enclosure w2*0.5+p0p_enclosure:y+gap+w2+p0p_enclosure))
			)
		else
			dbCreateRect( pcCellView "TMP" list( -p_minWidth*0.5:y+gap p_minWidth*0.5:y+gap+p_minWidth ) )
		)

		; include poly0
		if( (include_poly0==t) then
			dbCreateRect( pcCellView "POLY0" list( -width*0.5-p0p_enclosure:-p0p_enclosure width*0.5+p0p_enclosure:(bars+2)*(gap+p_minWidth)+gap+p0p_enclosure) )
		)

		; create stretch handles
		rodObj = rodGetObj( "" pcCellView )
		rodAssignHandleToParameter(
			?parameter	"width"
			?rodObj		rodObj
			?handleName	list( "centerLeft" "centerRight" )
			?displayName	"width"
			?stretchDir	"x"
			?userFunction	lambda( (SPCInfo) SPCInfo->paramVal + 2*SPCInfo->increment )
		)
		rodAssignHandleToParameter(
			?parameter	"bars"
			?rodObj		rodObj
			?handleName	"upperCenter"
			?displayName	"bars"
			?stretchDir	"y"
			?updateIncrement	p_minSpacing + gap
			?userFunction	lambda( (SPCInfo) SPCInfo->paramVal + round(SPCInfo->increment/SPCInfo->userData) )
			?userData	p_minWidth + gap
		)

		; Create the instNamePrefix property
		dbReplaceProp( pcCellView "instNamePrefix" "string" "spring" )
		; set version string
		dbReplaceProp( pcCellView "version" "string" "1.3.1" )
		; body SKILL code returns value t
		return(t)

	) ; end of body-of-SKILL-code prog

) ; ; end of pcDefinePCell