;================================================================================
; Robert Johnstone
; Simon Fraser University
;
; Last Modified:  2000/11/16
;
; Copyright 2000 Robert W. Johnstone
;--------------------------------------------------------------------------------

unless( boundp( 'admLibraryName )
	warn( "Setting the destination library to default value of ADM" )
	admLibraryName = "ADM"
)

pcDefinePCell(
	list( ddGetObj(admLibraryName) "vertical_support_2" "layout"
	) ; end of list for first argument

	(
		( height		130.0 )
		( width			150.0 )
		( slit_width1		2.0 )
		( slit_width2		2.1 )
		( slit_height1		10.0 )
		( slit_height2		10.0 )
		( include_poly0		"boolean"	nil )
	) ; end of parameter list

	prog( 
		; declare variables
		( pcTechFile rodObj
			p0p1_enclosure p_minSpacing p_nomSpacing pd_enclosure p_maxWidth 
                        h_nomWidth d_nomWidth d_maxSpacing
                        poly hole
			height2 height3 count_x count_y w x y tmp )

                ; set layers
                poly = "POLY2"
                hole = "HOLE2"

		; load tech file rules
		pcTechFile = techGetTechFile( pcCellView )
		p0p1_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" "POLY0" poly )
		unless( p0p1_enclosure  warn(strcat("minEnclosure rule for POLY0->" poly " not set")) )
		p_minSpacing = techGetSpacingRule( pcTechFile "minSpacing" poly )
		unless( p_minSpacing  warn(strcat("minSpacing rule for " poly " not set")) )
		p_nomSpacing = techGetSpacingRule( pcTechFile "nomWidth" poly )
		unless( p_nomSpacing  warn(strcat("nomWidth rule for " poly " not set")) )
		pd_enclosure = techGetOrderedSpacingRule( pcTechFile "minEnclosure" poly "DIMPLE" )
		unless( pd_enclosure  warn(strcat("minEnclosure rule for " poly "->DIMPLE not set")) )
		p_maxWidth = techGetSpacingRule( pcTechFile "maxWidth" poly )
		unless( p_maxWidth  warn(strcat("maxWidth rule for " poly " not set")) )
		h_nomWidth = techGetSpacingRule( pcTechFile "nomWidth" hole )
		unless( h_nomWidth  warn(strcat("nomWidth rule for " hole " not set")) )
		d_nomWidth = techGetSpacingRule( pcTechFile "nomWidth" "DIMPLE" )
		unless( d_nomWidth  warn("nomWidth rule for DIMPLE not set") )
		d_maxSpacing = techGetSpacingRule( pcTechFile "maxSpacing" "DIMPLE" )
		unless( d_maxSpacing  warn("maxSpacing rule for DIMPLE not set") )
		unless( d_maxSpacing>=p_maxWidth  warn(strcat("maxSpacing rule for DIMPLE is less than " poly " maxWidth")) )

		; check parameters
		height = if( (height<p_nomSpacing) p_nomSpacing height )
		slit_width1 = if( (slit_width1<p_minSpacing) p_minSpacing slit_width1 )
		slit_width2 = if( (slit_width2<p_minSpacing) p_minSpacing slit_width2 )
		slit_height1 = if( (slit_height1<p_nomSpacing) p_nomSpacing slit_height1 )
		slit_height2 = if( (slit_height2<p_nomSpacing) p_nomSpacing slit_height2 )
		width = if( (width<slit_width2+2*(slit_height2+p_nomSpacing)) slit_width2+2*(slit_height2+p_nomSpacing) width )
		
		; some calculations
		height2 = height + slit_height1
		height3 = height + slit_height1 + slit_height2

		; create polygon
		rodObj = rodCreatePolygon(
			?layer		poly 
			?pts		list(
				0:height slit_width1*0.5:height slit_width2*0.5:height2 slit_width2*0.5+slit_height2:height3
				slit_width2*0.5+slit_height2+p_nomSpacing:height3 width*0.5:p_nomSpacing width*0.5:0
				-width*0.5:0 -width*0.5:p_nomSpacing -slit_width2*0.5-slit_height2-p_nomSpacing:height3
				-slit_width2*0.5-slit_height2:height3 -slit_width2*0.5:height2 -slit_width1*0.5:height )
		)

		; create poly0 ground plane
		if( (include_poly0==t) then
			rodCreatePolygon(
				?layer		"POLY0"
				?fromObj	rodObj
				?size		p0p1_enclosure
			)
		)
		

		; create dimples
		count_y = ceiling( (height - d_nomWidth - 2*pd_enclosure) / d_maxSpacing )
		for( lp1 0 count_y
			; determine position of top of dimples
			y = height - pd_enclosure - lp1 * (height - d_nomWidth - 2*pd_enclosure) / count_y
			; calculate y offset compared to holes
			tmp = y-d_nomWidth*0.5 - (height - lp1 * height / count_y)
			tmp = tmp + (h_nomWidth - d_nomWidth)*0.5
			tmp = tmp + d_nomWidth + pd_enclosure
			
			w = width * ( 1 - y/height3 ) + ( slit_width2+2*slit_height2+p_nomSpacing ) * ( y / height3 )
			count_x = ceiling( w / d_maxSpacing )
			for( lp2 0 count_x
				; calculate x position for this row
				x = -w*0.5 + pd_enclosure + lp2 * (w-pd_enclosure*2-d_nomWidth) / count_x
				
				if( (lp2>0 && lp2<count_x && lp1>0 && lp1<count_y) then
					dbCreateRect( pcCellView "DIMPLE" list(	
						x:y-tmp
						x+d_nomWidth:y-d_nomWidth-tmp ) )
					
				else 
					dbCreateRect( pcCellView "DIMPLE" list( x:y x+d_nomWidth:y-d_nomWidth ) )
				)
			)
			
		)
		
		; create holes
		x = count_y
		count_y = ceiling( height / p_maxWidth )
		; align bands
		count_y = ceiling( (count_y+1.0) / x ) * x
		for( lp1 1 count_y-1
			y = lp1 * height / count_y

			w = width * ( 1 - y/height3 ) + ( slit_width2+2*slit_height2+p_nomSpacing ) * ( y / height3 )
			count_x = floor( w / p_maxWidth )
			for( lp2 1 count_x 
				x = lp2 * w / (count_x+1) - w / 2
				dbCreateRect( pcCellView hole list( x-h_nomWidth*0.5:y-h_nomWidth*0.5 x+h_nomWidth*0.5:y+h_nomWidth*0.5 ) )
			)
		)		
		
		; add stretch handles
		rodObj = rodGetObj( "" pcCellView )
		rodAssignHandleToParameter(
			?parameter	"width"
			?rodObj		rodObj
			?handleName	list( "lowerLeft" "lowerRight" )
			?displayName	"width"
			?stretchDir	"x"
			?userFunction	lambda( (SPCInfo) SPCInfo->paramVal + 2*SPCInfo->increment )
		)
		rodCreateHandle(
			?name		"height_handle"
			?rodObj		rodObj
			?type		"point"
			?value		0:height
		)
		rodAssignHandleToParameter(
			?parameter	"height"
			?rodObj		rodObj
			?handleName	list( "height_handle" )
			?displayName	"height"
			?stretchDir	"y"
		)

		; Create the instNamePrefix property
		dbReplaceProp( pcCellView "instNamePrefix" "string" "vertical_support" )
		; set version string
		dbReplaceProp( pcCellView "version" "string" "1.6.1" )
		; body SKILL code returns value t
		return(t)


	) ; end of body-of-SKILL-code prog

) ; ; end of pcDefinePCell