Chapter Contents

Previous

Next

Example 34.1: Investigating the Effect of Model Specification on Prediction

In the "Getting Started" section of the chapter on the VARIOGRAM procedure, a particular variogram is chosen for the coal seam thickness data. The chosen variogram is Gaussian with a scale (sill) of c₀=7.5, and a range of a₀=30. This choice of the variogram is based on a visual fit - a comparison of the plots of the regular and robust sample variograms and the Gaussian variogram for various scale (sill) and range values.

Another possible choice of model is the spherical variogram with the same scale (sill) of c₀=7.5 but with a range of a₀=60. This choice of range is again based on a visual fit; while not as good as the Gaussian model, the fit is reasonable.

It is generally held that spatial prediction is robust against model specification, while the standard error computation is not so robust.

This example investigates the effect of using these different models on the prediction and associated standard errors.

   data thick;
      input east north thick @@;
      datalines;
       0.7  59.6  34.1   2.1  82.7  42.2   4.7  75.1  39.5 
       4.8  52.8  34.3   5.9  67.1  37.0   6.0  35.7  35.9
       6.4  33.7  36.4   7.0  46.7  34.6   8.2  40.1  35.4   
      13.3   0.6  44.7  13.3  68.2  37.8  13.4  31.3  37.8
      17.8   6.9  43.9  20.1  66.3  37.7  22.7  87.6  42.8 
      23.0  93.9  43.6  24.3  73.0  39.3  24.8  15.1  42.3
      24.8  26.3  39.7  26.4  58.0  36.9  26.9  65.0  37.8 
      27.7  83.3  41.8  27.9  90.8  43.3  29.1  47.9  36.7
      29.5  89.4  43.0  30.1   6.1  43.6  30.8  12.1  42.8
      32.7  40.2  37.5  34.8   8.1  43.3  35.3  32.0  38.8
      37.0  70.3  39.2  38.2  77.9  40.7  38.9  23.3  40.5
      39.4  82.5  41.4  43.0   4.7  43.3  43.7   7.6  43.1
      46.4  84.1  41.5  46.7  10.6  42.6  49.9  22.1  40.7
      51.0  88.8  42.0  52.8  68.9  39.3  52.9  32.7  39.2
      55.5  92.9  42.2  56.0   1.6  42.7  60.6  75.2  40.1
      62.1  26.6  40.1  63.0  12.7  41.8  69.0  75.6  40.1
      70.5  83.7  40.9  70.9  11.0  41.7  71.5  29.5  39.8
      78.1  45.5  38.7  78.2   9.1  41.7  78.4  20.0  40.8
      80.5  55.9  38.7  81.1  51.0  38.6  83.8   7.9  41.6
      84.5  11.0  41.5  85.2  67.3  39.4  85.5  73.0  39.8 
      86.7  70.4  39.6  87.2  55.7  38.8  88.1   0.0  41.6
      88.4  12.1  41.3  88.4  99.6  41.2  88.8  82.9  40.5 
      88.9   6.2  41.5  90.6   7.0  41.5  90.7  49.6  38.9 
      91.5  55.4  39.0  92.9  46.8  39.1  93.4  70.9  39.7 
      94.8  71.5  39.7  96.2  84.3  40.3  98.2  58.2  39.5
      ;

   /*- Run KRIGE2D on original Gaussian model  ------------*/ 
   proc krige2d data=thick outest=est1;
      pred var=thick r=60;
      model scale=7.5 range=30 form=gauss;
      coord xc=east yc=north;
      grid x=0 to 100 by 10 y=0 to 100 by 10;
   run;

   /*- Run KRIGE2D using Spherical Model, modified range  -*/ 
   proc krige2d data=thick outest=est2;
      pred var=thick r=60;
      model scale=7.5 range=60 form=spherical;
      coord xc=east yc=north;
      grid x=0 to 100 by 10 y=0 to 100 by 10;
   run;

   data compare ;
      merge est1(rename=(estimate=g_est stderr=g_std))
            est2(rename=(estimate=s_est stderr=s_std));
      est_dif=g_est-s_est;
      std_dif=g_std-s_std;
   run;                     

   proc print data=compare;
      title 'Comparison of Gaussian and Spherical Models';
      title2 'Differences of Estimates and Standard Errors';
      var gxc gyc npoints g_est s_est est_dif  g_std s_std 
                          std_dif;
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.