* Working computer problem # 5
sample 1 104
* Part I *********************************************
sample 1 50
* Ramanathan, data set 4-5
set nocolor
read(a:data4-5) wlfp yf ym educ ue mr dr urb wh
* All variables included for AUXRSQ
ols wlfp yf ym educ ue mr dr urb wh/auxrsq
* Running one AUX equation to look for pattern
ols yf ym educ ue mr dr urb wh
* Ridge regression
ols wlfp yf ym educ ue mr dr urb wh/ridge=.3
* Principal components
pcomp yf ym educ ue mr dr urb wh &
/pcomp=pc pcinfo=info
* Using the first three components
ols wlfp pc:1 pc:2 pc:3/pcinfo=info pcomp=pc
stat pc:1 pc:2 pc:3 yf ym educ ue mr dr urb wh/pcor
* Using components 1-5 and 7
ols wlfp pc:1 pc:2 pc:3 pc:4 pc:5 pc:7/pcinfo=info pcomp=pc
stat pc:4 pc:5 pc:7 yf ym educ ue mr dr urb wh/pcor
* Part II *********************************************
* Working the second part of computer problem # 5
sample 1 104
read(a:data7-8) grth y60 inv pop school dn di doecd 
genr egrth=exp(grth)
genr inv2=inv**2
genr linv=log(inv)
* The author's version (LOGLIN)
ols grth inv/loglin predict=lgh
* Linear
ols egrth inv
* Quadratic 
ols egrth inv inv2
* Trying LINLOG
ols egrth linv/linlog
* Trying LOGLOG
ols grth linv/loglog
* Checking Box-Cox regarding LOGLIN (only LHS transformed)
box egrth inv
* Checking BOX-Cox regarding LOGLOG
box egrth inv/all
* Checking Box-Cox regarding LINLOG
box egrth inv/tidwell
* Graphing
genr gh=exp(lgh)
sort inv egrth gh
plot egrth gh inv/vga lineonly