Chapter Contents
Previous
Next
The GREPLAY Procedure

Example 2: Replaying Graphics Output in a Template

Procedure features:
GREPLAY statement options:
GOUT=
IGOUT=
TEMPLATE=
TREPLAY statement
Other features:
PROC GSLIDE
Sample library member: GR26N02

[IMAGE]

The TREPLAY statement replays into the template NEWTEMP four catalog entries that contain graphics output. The NEWTEMP template is defined in Creating a Template. It contains four equally sized panels and one large, full-size panel. Note that assignments are made to all but one of the panels. Because the fourth panel is not listed in the TREPLAY statement, it does not appear in the graphics output. The HSIZE= and VSIZE= options are adjusted and then reset to default in order to reflect the dimensions of the different-sized template panels.
 Note about code
libname reflib 'SAS-data-library';
goptions reset=all gunit=pct border
         cback=white colors=(black blue green red)
         ftext=swiss htitle=8 htext=5 nodisplay
         hsize=4in vsize=3.8in;
 Note about code
proc gslide gout=reflib.grafcat;
   title c=red 'Graph Number 1';
   footnote h=3 j=r 'GR26N02(a) ';
run;
   title 'Graph Number 2';
   footnote h=3 j=r 'GR26N02(b) ';
run;
   title 'Graph Number 3';
   footnote h=3 j=r 'GR26N02(c) ';
run;
 Note about code
goptions hsize=0in vsize=0in;
proc gslide gout=reflib.grafcat;
   title 'Common Title';
   footnote 'Common Footnote';
run;
 Note about code
goptions display;
 Note about code
proc greplay igout=reflib.grafcat gout=reflib.excat
             tc=reflib.tempcat nofs;
   template=newtemp;
 Note about code
   treplay 1:gslide
           2:gslide1
           3:gslide2
           5:gslide3;
quit;


Chapter Contents
Previous
Next
Top of Page

Copyright 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.