The REPORT Procedure

Example 4: Consolidating Multiple Observations into One Row of a Report

Procedure features:

BREAK statement options:

	OL
	SKIP
	SUMMARIZE
	SUPPRESS

CALL DEFINE statement

Compute block

associated with a data set variable

COMPUTE statement arguments:

	AFTER
	a data set variable as report-item

DEFINE statement options:

	ANALYSIS
	GROUP
	SUM
	customizing column headers

LINE statement:

	quoted text
	variable values

Data set:

GROCERY

Formats:

$MGRFMT. and $DEPTFMT.

This example creates a summary report that

consolidates information for each combination of Sector and Manager into one row of the report
contains default summaries of sales for each sector
contains a customized summary of sales for all sectors
uses one format for sales in detail rows and a different format in summary rows
uses customized column headers.

Program

libname proclib 'SAS-data-library';

options nodate pageno=1 linesize=64 pagesize=60
        fmtsearch=(proclib);

proc report data=grocery nowd headline headskip;

   column sector manager sales;

   define sector / group
                   format=$sctrfmt.
                   'Sector';
   define manager / group
                    format=$mgrfmt.
                    'Manager';
   define sales / analysis sum
                  format=comma10.2
                  'Sales';

   break after sector / ol
                        summarize
                        suppress
                        skip;

   compute after;
      line 'Combined sales for the northern sectors were '
            sales.sum dollar9.2 '.';
   endcomp;

   compute sales;
      if _break_ ne ' ' then
      call define(_col_,"format","dollar11.2");
   endcomp;

   where sector contains 'n';
   title 'Sales Figures for Northern Sectors';
run;

Output

Chapter Contents
Previous
Next
Top of Page