The DATASETS Procedure

Example 3: Modifying SAS Data Sets

Procedure features:

PROC DATASETS statement option:

NOLIST

FORMAT statement

INDEX CREATE statement options:

	NOMISS
	UNIQUE

INFORMAT statement

LABEL statement

MODIFY statement options:

	LABEL=
	READ=
	SORTEDBY=

RENAME statement

This example modifies two SAS data sets using the MODIFY statement and statements subordinate to it. Describing a SAS Data Set shows the modifications to the GROUP data set.

Tasks include

modifying SAS files
labeling a SAS data set
adding a READ password to a SAS data set
indicating how a SAS data set is currently sorted
creating an index for a SAS data set
assigning informats and formats to variables in a SAS data set
renaming variables in a SAS data set
labeling variables in a SAS data set.

Program

options pagesize=40 linesize=80 nodate pageno=1 source;

libname health 'SAS-data-library';

proc datasets library=health nolist;

   modify group (label='Test Subjects' read=green sortedby=lname);

      index create vital=(birth salary) / nomiss unique;

      informat birth date7.;
      format birth date7.;

      label salary='current salary excluding bonus';

   modify oxygen;
      rename oxygen=intake;
      label intake='Intake Measurement';
quit;

SAS Log

1 options pagesize=40 linesize=80 nodate pageno=1 source; 2 3 proc datasets library=health nolist; 4 5 modify group (label='Test Subjects' read=XXXXX sortedby=lname); WARNING: The file HEALTH.GROUP.DATA is not ALTER protected. It could be deleted or replaced without knowing the password. 6 7 index create vital=(birth salary) / nomiss unique; NOTE: Composite index vital has been defined. 8 9 informat birth date7.; 10 format birth date7.; 11 label salary='current salary excluding bonus'; 12 13 modify oxygen; 14 rename oxygen=intake; NOTE: Renaming variable oxygen to intake. 15 label intake='Intake Measurement'; 16 quit;

Chapter Contents
Previous
Next
Top of Page