The CHART Procedure

Example 3: Subdividing the Bars into Categories

Procedure features:

VBAR statement options:

	SUBGROUP=
	SUMVAR=

This example

produces a vertical bar chart for categories of one variable with bar lengths that represent the values of another variable.
subdivides each bar into categories based on the values of a third variable.

Program

options nodate pageno=1 linesize=80 pagesize=60;

data piesales;
   input Bakery $ Flavor $ Year Pies_Sold;
   datalines;
Samford  apple      1995  234
Samford  apple      1996  288
Samford  blueberry  1995  103
Samford  blueberry  1996  143
Samford  cherry     1995  173
Samford  cherry     1996  195
Samford  rhubarb    1995   26
Samford  rhubarb    1996   28
Oak      apple      1995  319
Oak      apple      1996  371
Oak      blueberry  1995  174
Oak      blueberry  1996  206
Oak      cherry     1995  246
Oak      cherry     1996  311
Oak      rhubarb    1995   51
Oak      rhubarb    1996   56
Clyde    apple      1995  313
Clyde    apple      1996  415
Clyde    blueberry  1995  177
Clyde    blueberry  1996  201
Clyde    cherry     1995  250
Clyde    cherry     1996  328
Clyde    rhubarb    1995   60
Clyde    rhubarb    1996   59
;

proc chart data=piesales;
   vbar flavor / subgroup=bakery

                 sumvar=pies_sold;
   title 'Pie Sales by Flavor Subdivided by Bakery Location';
run;

Output

The bar that represents the sales of apple pies, for example, shows 1,940 total pies across both years and all three bakeries. The symbol for the Samford Avenue bakery represents the 522 pies at the top, the symbol for the Oak Street bakery represents the 690 pies in the middle, and the symbol for the Clyde Drive bakery represents the 728 pies at the bottom of the bar for apple pies. By default, the labels along the horizontal axis are truncated to eight characters.

Chapter Contents
Previous
Next
Top of Page