Chapter Contents

Previous

Next

Example 23.5: Computing a Distance Matrix

A wide variety of distance and similarity measures are used in cluster analysis (Anderberg 1973, Sneath and Sokal 1973). If your data are in coordinate form and you want to use a non-Euclidean distance for clustering, you can compute a distance matrix using a DATA step or the IML procedure.

Similarity measures must be converted to dissimilarities before being used in PROC CLUSTER. Such conversion can be done in a variety of ways, such as taking reciprocals or subtracting from a large value. The choice of conversion method depends on the application and the similarity measure.

In the following example, the observations are states. Binary-valued variables correspond to various grounds for divorce and indicate whether the grounds for divorce apply in each of the states.

The %DISTANCE^* macro is used to compute the Jaccard coefficient (Anderberg 1973, pp. 89, 115, and 117) between each pair of states. The Jaccard coefficient is defined as the number of variables that are coded as 1 for both states divided by the number of variables that are coded as 1 for either or both states. The Jaccard coefficient is converted to a distance measure by subtracting it from 1.

   %include '<location of  SAS/STAT sample library>/xmacro.sas';
   %include '<location of  SAS/STAT sample library>/distnew.sas';

   options ls=120 ps=60;
   data divorce;
      title 'Grounds for Divorce';
      input state $15.
            (incompat cruelty desertn non_supp alcohol 
             felony impotenc insanity separate) (1.) @@;
      if mod(_n_,2) then input +4 @@; else input;
      datalines;
   ALABAMA        111111111    ALASKA         111011110
   ARIZONA        100000000    ARKANSAS       011111111
   CALIFORNIA     100000010    COLORADO       100000000
   CONNECTICUT    111111011    DELAWARE       100000001
   FLORIDA        100000010    GEORGIA        111011110
   HAWAII         100000001    IDAHO          111111011
   ILLINOIS       011011100    INDIANA        100001110
   IOWA           100000000    KANSAS         111011110
   KENTUCKY       100000000    LOUISIANA      000001001
   MAINE          111110110    MARYLAND       011001111
   MASSACHUSETTS  111111101    MICHIGAN       100000000
   MINNESOTA      100000000    MISSISSIPPI    111011110
   MISSOURI       100000000    MONTANA        100000000
   NEBRASKA       100000000    NEVADA         100000011
   NEW HAMPSHIRE  111111100    NEW JERSEY     011011011
   NEW MEXICO     111000000    NEW YORK       011001001
   NORTH CAROLINA 000000111    NORTH DAKOTA   111111110
   OHIO           111011101    OKLAHOMA       111111110
   OREGON         100000000    PENNSYLVANIA   011001110
   RHODE ISLAND   111111101    SOUTH CAROLINA 011010001
   SOUTH DAKOTA   011111000    TENNESSEE      111111100
   TEXAS          111001011    UTAH           011111110
   VERMONT        011101011    VIRGINIA       010001001
   WASHINGTON     100000001    WEST VIRGINIA  111011011
   WISCONSIN      100000001    WYOMING        100000011
   ;

   %distance(data=divorce, id=state, options=nomiss, out=distjacc,
             shape=square, method=djaccard, var=incompat--separate);

   proc print data=distjacc(obs=10);
      id state; var alabama--georgia;
      title2 'First 10 states';
   run;
   title2;

   proc cluster data=distjacc method=centroid 
                pseudo outtree=tree;
      id state;
      var alabama--wyoming;
   run;

   proc tree data=tree noprint n=9 out=out;
      id state;
   run;

   proc sort;
      by state;
   run;

   data clus;
      merge divorce out;
      by state;
   run;

   proc sort;
      by cluster;
   run;

   proc print;
      id state;
      var incompat--separate;
      by cluster;
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.