model
{

# m = number of subjects ;  g = number of groups ;  k = number of occasions
	
  for(g in 1:6) { for(i in 1:m-1) { for(j in i+1:m)  { for (k in 1:5)  {

  y[g,(i-1)*m-i*(i-1)/2 +j-i,k,1:2] ~
  dmnorm(Ey[g,(i-1)*m-i*(i-1)/2+j-i,k,1:2],S[k,1:2,1:2]) 
				
  Ey[g,(i-1)*m-i*(i-1)/2+j-i,k,1] <- mu+a[g,i]+b[g,j] 
  Ey[g,(i-1)*m-i*(i-1)/2+j-i,k,2] <- mu+a[g,j]+b[g,i] 
						
  } } } }		
	
  for (g in 1:6) { for (i in 1:m) {
   a[g,i] <- aa[(g-1)*m+i,1]
   b[g,i] <- aa[(g-1)*m+i,2]  
  } }
		
# Prior for mu as described in (11)

  mu ~ dnorm(theta,tau) 

# Hyperpriors as described in (14)

  theta ~ dnorm(0,0.0001); tau ~ dgamma(0.0001,0.0001)
	
  Sab[1:2,1:2] ~ dwish(Omega[1:2,1:2],2) 
	 
  Sigma[1:2,1:2] <- inverse(Sab[1:2,1:2]) 
  siga <- Sigma[1,1] ;  sigb <- Sigma[2,2]	
  corrab <- Sigma[1,2]/(sqrt(Sigma[1,1]*Sigma[2,2]))
 
  for (k in 1:5) {	  	  
  taug[k] ~ dgamma(3,A02); sigg[k] <- 1/taug[k]  
  
  corrg[k] ~ dunif(-1,1) 
	
  S[k,1,1] <-  taug[k]/(1-corrg[k]*corrg[k])
  S[k,1,2] <- -corrg[k]*taug[k]/(1-corrg[k]*corrg[k])
  S[k,2,1] <- S[k,1,2]; S[k,2,2] <-  S[k,1,1]
	
  }
  A02 <- 100	
		
# DP Priors for alpha's and beta's as in (15) using stick-breaking method
				
  for (j in 1:48) {  for (kk in 1:2) {		 
  aa[j,kk] <- theta1[latent[j],kk]
  }  }
  for (i in 1:48) {		  
  latent[i] ~ dcat(pi[1:L1])
  }
  pi[1] <- r[1]
 
  for (j in 2:(L1-1)) { 
  log(pi[j]) <- log(r[j])+sum(R1[j,1:j-1])

  for (l in 1:j-1) {
  R1[j,l] <- log(1-r[l])
  } }
  
  pi[L1] <- 1-sum(pi[1:(L1-1)])
		
  for (j in 1:L1) {
  r[j] ~ dbeta(1,alpha)
  }
		
# Baseline distribution for DP as in (12)

 for (i in 1:L1) {		
 theta1[i,1:2] ~ dmnorm(zero[1:2],Sab[1:2,1:2]) 
 }
 zero[1] <- 0; zero[2] <- 0
		
# Prior for concentration parameter
  alpha ~ dgamma(2,1)

}