Chapter Contents

Previous

Next

Example 2.10: Multiple Calendars

This example illustrates the use of multiple calendars within a project. Different scenarios are presented to show the use of different calendars and how project schedules are affected. Output 2.10.1 shows the data set WORKDATA, which defines several shift patterns. These shift patterns are appropriately associated with three different calendars in the data set CALEDATA, also shown in the same output. The three calendars are defined as follows:

• The DEFAULT calendar has five eight-hour days (Monday through Friday) and holidays on Saturday and Sunday.
• The calendar OVT_CAL specifies an overtime calendar that has 10-hour work days on Monday through Friday and a half day on Saturday and a holiday on Sunday.
• The calendar PROD_CAL follows a more complicated work pattern: Sunday is a holiday; on Monday work is done from 8 a.m. through midnight with a two hour break from 6 p.m. to 8 p.m.; on Tuesday through Friday work is done round the clock with two 2-hour breaks from 6 a.m. to 8 a.m. and 6 p.m. to 8 p.m.; on Saturday the work shifts are from midnight to 6 a.m. and again from 8 a.m. to 6 p.m. In other words, work is done continuously from 8 a.m. on Monday morning to 6 p.m. on Saturday with two hour breaks every day at 6 a.m. and 6 p.m.

An easy way to visualize all the breaks and holidays for each calendar is to use a Gantt chart, plotting a bar for each calendar from the start of the project to January 2, 1992, with all the holiday and work shift specifications. The following program produces Output 2.10.3. Note that holidays and breaks are marked with a solid fill pattern.

   goptions hpos=160 vpos=25 ftext=swiss;
   title h=1.5 'Multiple Calendars';
   title2 'Breaks and Holidays for the Different Calendars';
   proc gantt data=cals graphics
              calendar=calendar holidata=holidays
              workday=workdata;
      chart / interval=dtday mininterval=dthour skip=2
              holiday=(holiday) holifin=(holifin)
              markbreak daylength='08:00't calid=cal
              ref='2dec91:00:00'dt to '2jan92:00:00'dt by dtday
              nolegend nojobnum increment=16
              hpages=6;
      id cal;
      run;

PROC CPM is first invoked without reference to the CALID variable. Thus, the procedure recognizes only the first observation in the Calendar data set (a warning is issued to the log to this effect), and only the default calendar is used for all activities in the project. The daylength parameter is interpreted as the length of a standard work day; all the durations are assumed to be in units of this standard work day. Output 2.10.4 displays the schedule obtained. Note that the project is scheduled to finish on March 13, 1992, at 12 noon.

   data widgcal;
      set widget9;
      if task = 'Production' then       cal = 'PROD_CAL';
      else if task = 'Prototype' then   cal = 'OVT_CAL';
      else                              cal = 'DEFAULT';
      run;

   proc cpm date='02dec91'd data=widgcal out=scheddef
            holidata=holidays daylength='08:00't
            workday=workdata
            calendar=calendar;
      holiday holiday / holifin = holifin;
      activity task;
      duration days;
      successor succ1 succ2 succ3;
      run;

title2 'Project Schedule: Default calendar';
proc print;
   var task days e_start e_finish l_start l_finish
       t_float f_float;
   run;

   proc cpm date='02dec91'd data=widgcal out=schedmc
            holidata=holidays daylength='08:00't
            workday=workdata
            calendar=calendar;
      holiday holiday / holifin = holifin;
      activity task;
      duration days;
      successor succ1 succ2 succ3;
      calid cal;
      run;

title2 'Project Schedule: Three Calendars';
proc print;
   var task days cal e_: l_: t_float f_float;
   run;

   /* Create a data set to illustrate holidays with PROC GANTT */
   data cals2;
      e_start='2dec91:00:00'dt;
      e_finish='19dec91:00:00'dt;
      label cal ='Schedule Breaks / Holidays';
      format e_start e_finish datetime16.;
      length cal $8.;
      cal='DEFAULT' ; output;
      cal='Eng_cal' ; output;
      run;

   title2 'Breaks and Holidays for Eng_cal and the DEFAULT Calendar';
   proc gantt data=cals2 graphics
              calendar=caledata holidata=holidata
              workday=workdata;
      chart / interval=dtday mininterval=dthour skip=2
              holiday=(holiday) holifin=(holifin) holidur=(holidur)
              markbreak daylength='08:00't calid=cal
              ref='2dec91:00:00'dt to '19dec91:00:00'dt by dtday
              nojobnum nolegend increment=16 hpages=3;
      id cal;
      run;

   data widgvac;
      set widgcal;
      if task = 'Write Specs' then cal = 'Eng_cal';
      run;

   proc cpm date='02dec91'd data=widgvac out=schedvac
            holidata=holidata daylength='08:00't
            workday=workdata
            calendar=caledata;
      holiday holiday / holifin = holifin holidur=holidur;
      activity task;
      duration days;
      successor succ1 succ2 succ3;
      calid cal;
      run;

title2 'Project Schedule: Four Calendars';
proc print;
   var task days cal e_: l_: t_float f_float;
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.