Chapter Contents

Previous

Next

Example 2.24: Multiproject Scheduling

This example illustrates multiproject scheduling.

Consider a Survey project that contains three phases, Plan, Prepare, and Implement, with each phase containing more than one activity. You can consider each phase of the project as a subproject within the master project, Survey. Each subproject in turn contains the lowest level activities, also referred to as the leaf tasks. The Activity data set, containing the task durations, project hierarchy, and the precedence constraints, is displayed in Output 2.24.1.

The PROJECT and ACTIVITY variables together define the project hierarchy using the parent/child relationship. Thus, the subproject, `Plan', contains the two leaf tasks, `plan sur' and `design q'. Precedence constraints are specified between leaf tasks as well as between subprojects. For example, the subproject `Prepare' is followed by the subproject `Implement'. Durations are specified for all the tasks in the project, except for the master project `Survey'.

In addition to the Activity data set, define a Holiday data set, also displayed in Output 2.24.1.

Note that the PROJ_DUR variable is missing for all the leaf tasks, and it contains the project duration for the supertasks. The project duration is computed as the span of all the subtasks of the supertask. The PROJ_LEV variable specifies the level of the subtask within the tree defining the project hierarchy, starting with the level `0' for the master project (or the root), `Survey'. The variable WBS_CODE contains the Work Breakdown Structure code defined by the CPM procedure using the project hierarchy.

   proc cpm data=survey date='3apr95'd out=survout1
            interval=weekday holidata=holidata;
      activity   activity;
      successor  succ1-succ3;
      duration   duration;
      id         id;
      holiday    hol;
      project    project / orderall addwbs;
      run;


   proc sort;
      by es_asc;
      run;

   title 'Conducting a Market Survey';
   title2 'Early and Late Start Schedule';
   proc print;
      run;

   data gant;
      length id $26.;
      set survout1;
      if proj_lev=1 then id="   "||id;
      else if proj_lev=2 then id="      "||id;
      run;

   goptions hpos=80 vpos=43;
   title c=black f=swiss 'Conducting a Market Survey';
   title2 c=black f=swiss h=1.5 'Project Schedule';

   proc gantt graphics data=gant holidata=holidata;
      chart / holiday=(hol)
              interval=weekday
              font=swiss skip=2 height=1.2
              nojobnum
              compress noextrange
              activity=activity succ=(succ1-succ3)
              cprec=cyan cmile=magenta
              caxis=black cframe=ligr;
      id   id;
   run;

   title 'Market Survey';
   title2 'Summary Schedule';
   proc print data=survout1;
      where proj_lev=1;
      id activity;
      var proj_dur duration e_start--t_float;
      run;

   title 'Market Survey';
   title2 'Sub-Project Schedule';
   proc print data=survout1;
      where substr(WBS_CODE,1,3) = "0.1";
      id activity;
      var project--activity duration e_start--t_float;
      run;

First, suppose you impose a FINISHBEFORE constraint on the Survey project by specifying the FBDATE to be May 15, 1995. The following program schedules the project with a project start and finish specification. The resulting summary schedule for the subprojects is shown in Output 2.24.6. Note that the late finish time of the project is the 12th of May because there is a weekend on the 13th and 14th of May, 1995.

   proc cpm data=survey date='3apr95'd out=survout2
            interval=weekday holidata=holidata
            fbdate='15may95'd; /* project finish date */
      activity   activity;
      successor  succ1-succ3;
      duration   duration;
      id         id;
      holiday    hol;
      project    project / orderall addwbs;
      run;

   title 'Market Survey';
   title2 'Summary Schedule: FBDATE Option';
   proc print data=survout2;
      where proj_lev=1;  /* First level subprojects */
      id activity;
      var proj_dur duration e_start--t_float;
      run;

                                              E_START + duration

and this value is used during the backward pass.

The summary schedule resulting from the use of the USEPROJDUR option is shown in Output 2.24.8. Note the difference in the schedules in Output 2.24.7 and Output 2.24.8. In Output 2.24.7, the computed project duration, PROJ_DUR, is used to set an upper bound on the late finish time of each subproject, while in Output 2.24.8, the specified project duration is used for the same purpose. Here, only the summary schedules are displayed; the effect of the two options on the subtasks within each subproject can be seen by displaying the entire schedule in each case. A Gantt chart of the entire project is displayed in Output 2.24.9.

   data survey2;
      format aldate date7.;
      set survey;
      if activity="Implement" then do;
         altype="fle";
         aldate='10may95'd;
         end;

      run;

   proc cpm data=survey2 date='3apr95'd out=survout5
            interval=weekday holidata=holidata
            fbdate='15jun95'd;
      activity   activity;
      successor  succ1-succ3;
      duration   duration;
      id         id;
      holiday    hol;
      project    project / orderall addwbs sepcrit useprojdur;
      aligntype  altype;
      aligndate  aldate;
      run;

   title 'Market Survey';
   title2 'USEPROJDUR option and Alignment date';
   proc print;
      where proj_lev=1;
      id activity;
      var proj_dur duration e_start--t_float;
      run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.