Example 1.3: Displaying a Confidence Interval for Cpk

PROC CAPABILITY and General Statements

Example 1.3: Displaying a Confidence Interval for Cpk

See CAPSPEC3 in the SAS/QC Sample Library

In this example, the capability index C_pk is computed for the amplification data in AMPS. To examine the accuracy of this estimate, the following statements calculate a 90% confidence interval for C_pk, then display the interval on a histogram (shown in Output 1.3.1) using the INSET statement:

   title 'Boosting Power of Telephone Amplifiers';
   legend1 FRAME CFRAME=ligr CBORDER=black POSITION=center;
   proc capability data=amps noprint alpha=0.10;
      var decibels;
      spec  target = 5    lsl = 4       usl = 6
           ltarget = 2   llsl = 3      lusl = 4
           ctarget = red clsl = yellow cusl = yellow;
      histogram decibels / cframe   = ligr
                           cfill    = steel
                           cbarline = white
                           legend   = legend1;
      inset cpklcl cpk cpkucl / header = '90% Confidence Interval'
                                format = 6.3
                                cframe = black
                                ctext  = black
                                cfill  = blank;
   run;

The ALPHA= option in the PROC CAPABILITY statement controls the level of the confidence interval. In this case, the 90% confidence interval on C_pk is wide (from 0.328 to 0.496), indicating that the process may need adjustments in order to improve process variability. Confidence limits for capability indices can be displayed using the INSET statement (as shown in Output 1.3.1) or saved in an output data set using the OUTPUT statement. For formulas and details about capability indices, see "Specialized Capability Indices" . For more information about the INSET statement, see Chapter 5, "INSET Statement".

Output 1.3.1: Confidence Interval on C_pk

The following statements can be used to produce a table of process capability indices including the index C_pk:

   ods select indices;
   proc capability data=amps alpha=0.10;
      spec  target = 5  lsl = 4  usl = 6
           ltarget = 2 llsl = 3 lusl = 4;
      var decibels;
   run;

Output 1.3.2: Process Capability Indices

Boosting Power of Telephone Amplifiers

The CAPABILITY Procedure

Variable: decibels (Amplification in Decibels (dB))

Process Capability Indices
Index	Value	90% Confidence Limits
Cp	0.508962	0.439538	0.576922
CPL	0.411920	0.326620	0.495136
CPU	0.606004	0.501261	0.708127
Cpk	0.411920	0.327599	0.496241
Cpm	0.488674	0.425292	0.556732

Chapter Contents
Previous
Next
Top