Example 15.7: Mixed-Level Design Using Design Replication and Point Replication

Details of the FACTEX Procedure

Example 15.7: Mixed-Level Design Using Design Replication and Point Replication

See FACTEX13 in the SAS/QC Sample Library

Orthogonal factorial designs are most commonly used at the initial stages of experimentation. At these stages, it is best to experiment with as few levels of each factor as possible in order to minimize the number of runs required. Thus, these designs usually involve only two levels of each factor. Occasionally some factors will naturally have more than two levels of interest -different types of seed, for instance.

You can create designs for factors with different numbers of levels simply by taking the cross product of component designs in which the factors all have the same numbers of levels, that is, replicating every run of one design for each run of the other. (See Example 15.14.) All estimable effects in each of the component designs, as well as all generalized interactions between estimable effects in different component designs, are estimable in the cross-product; refer to Section 3 of Chakravarti (1956).

This example illustrates how you can construct a mixed level design using the OUTPUT statement with the POINTREP= option or the DESIGNREP= option to take the cross product between two designs.

Suppose you want to construct a mixed-level factorial design for two two-level factors (A and B) and one three-level factor (C) with 12 runs. The following SAS statements produce a complete 3×2² factorial design using design replication:

   proc factex;
      factors a b;        
      output out=ab;            
   run;
      factors c / nlev=3;        
      output out=drepdesn     
             designrep=ab;
   run;

   proc print data=drepdesn;
   run;

Output 15.7.1 lists the mixed-level design saved in the data set DREPDESN.

Output 15.7.1: 3×2² Mixed-Level Design Using Design Replication

Obs	a	b	c
1	-1	-1	-1
2	-1	-1	0
3	-1	-1	1
4	-1	1	-1
5	-1	1	0
6	-1	1	1
7	1	-1	-1
8	1	-1	0
9	1	-1	1
10	1	1	-1
11	1	1	0
12	1	1	1

You can also create a mixed-level design for the preceding factors using the point replication feature of the FACTEX procedure. The following SAS statements produce a complete 2²×3 factorial design using point replication:

   proc factex;
      factors a b;              
      output out=ab;         
   run;
      factors c / nlev=3;        
      output out=prepdesn     
             pointrep=ab;
   run;

   proc print data=prepdesn;
   run;

Output 15.7.2 lists the mixed-level design saved in the data set PREPDESN.

Output 15.7.2: 2²×3 Mixed-Level Design Using Point Replication

Obs	c	a	b
1	-1	-1	-1
2	-1	-1	1
3	-1	1	-1
4	-1	1	1
5	0	-1	-1
6	0	-1	1
7	0	1	-1
8	0	1	1
9	1	-1	-1
10	1	-1	1
11	1	1	-1
12	1	1	1

Note the difference between the designs in Output 15.7.1 and Output 15.7.2. In design replication, the mixed-level design is given by AB $\otimes$ C, while for point replication the mixed-level design is given by C $\otimes$ AB, where $\otimes$ denotes the direct product. In design replication, you can view the DESIGNREP= data set as nested outside the design, while in point replication, you can view the POINTREP= data set as nested inside the design.

Chapter Contents
Previous
Next
Top