Example 41.1: Applying Tests for Special Causes

UCHART Statement

Example 41.1: Applying Tests for Special Causes

See SHWUEX1 in the SAS/QC Sample Library

This example illustrates how you can apply tests for special causes to make u charts more sensitive to special causes of variation.

A textile company inspects rolls of fabric for defects. The rolls are one meter wide and 30 meters long. The following statements create a SAS data set named FABRIC3, which contains the number of fabric defects for 20 rolls of fabric:

   data fabric3;
      input roll defects @@;
      datalines;
    1   6    2   9    3  14    4  17
    5   3    6   8    7   9    8   2
    9  14   10   1   11   3   12   5
   13   6   14   9   15  10   16  12
   17  11   18   4   19   9   20   4
   ;

The following statements create a u chart and tabulate the information on the chart. The chart and tables are shown in Output 41.1.1 and Output 41.1.2.

   title1 'u Chart for Fabric Defects';
   title2 'Tests=1 to 4';
   symbol v=dot c=vig;
   proc shewhart data=fabric3;
      uchart defects*roll / subgroupn = 30
                            tests     = 1 to 4
                            ltests    = 20
                            zonelabels
                            tabletests
                            cframe    = steel
                            cinfill   = ligr
                            ctests    = black
                            coutfill  = yellow
                            cconnect  = vig;
   run;

The TESTS= option requests Tests 1, 2, 3, and 4, which are described in Chapter 48, "Tests for Special Causes." Only Tests 1, 2, 3, and 4 are recommended for u charts. The ZONELABELS option requests the zone lines, which are used to define the tests, and displays labels for the zones. The LTESTS= option specifies the line type used to connect the points in a pattern for a test that is signaled. The TABLETESTS option requests a table of the values of u_i and the control limits, together with a column indicating the subgroups at which the tests are positive.

Output 41.1.1 and Output 41.1.2 indicate that Test 1 is positive for Roll 4 and Test 3 is positive at Roll 15.

Output 41.1.1: Tests for Special Causes Displayed on u Chart

Output 41.1.2: Tabular Form of u Chart

u Chart for Fabric Defects

Tests=1 to 4

The SHEWHART Procedure

u Chart Summary for defects
roll	Subgroup Sample Size	3 Sigma Limits with n=30 for Count per Unit			Special Tests Signaled
roll	Subgroup Sample Size	Lower Limit	Subgroup Count per Unit	Upper Limit	Special Tests Signaled
1	30.0000	0	0.20000000	0.53928480
2	30.0000	0	0.30000000	0.53928480
3	30.0000	0	0.46666667	0.53928480
4	30.0000	0	0.56666667	0.53928480	1
5	30.0000	0	0.10000000	0.53928480
6	30.0000	0	0.26666667	0.53928480
7	30.0000	0	0.30000000	0.53928480
8	30.0000	0	0.06666667	0.53928480
9	30.0000	0	0.46666667	0.53928480
10	30.0000	0	0.03333333	0.53928480
11	30.0000	0	0.10000000	0.53928480
12	30.0000	0	0.16666667	0.53928480
13	30.0000	0	0.20000000	0.53928480
14	30.0000	0	0.30000000	0.53928480
15	30.0000	0	0.33333333	0.53928480	3
16	30.0000	0	0.40000000	0.53928480
17	30.0000	0	0.36666667	0.53928480
18	30.0000	0	0.13333333	0.53928480
19	30.0000	0	0.30000000	0.53928480
20	30.0000	0	0.13333333	0.53928480

Chapter Contents
Previous
Next
Top