Preliminary Examination of Variation

Specialized Control Charts

Preliminary Examination of Variation

As a preliminary step in the analysis, the data are sorted by lane and visually screened for outliers (test values greater than 130) with box plots created as follows:

   proc sort data=film;
      by lane;

   symbol v=dot c=yellow;
   title 'Outlier Analysis';
   proc shewhart data=film;
      boxchart testval*lane / boxstyle = schematicid
                              idsymbol = dot
                              cframe   = vigb
                              cboxfill = vlib
                              cboxes   = yellow
                              vref     = 130
                              vreflab  = 'Outlier Cutoff'
                              hoffset  = 5
                              nolegend
                              stddevs
                              nolimits ;
      id sample;
   run;

Specifying BOXSTYLE=SCHEMATICID requests schematic box plots with outliers identified by the value of the ID variable SAMPLE. The STDDEVS option specifies that the estimate of the process standard deviation is to be based on subgroup standard deviations. Although this estimate is not needed here because control limits are not displayed, it is recommended that you specify the STDDEVS option whenever you are working with subgroup sample sizes greater than ten. The NOLEGEND and NOLIMITS options suppress the subgroup sample size legend and control limits for lane means that are displayed by default. The display is shown in Figure 49.8.

Figure 49.8: Outlier Analysis for the Data Set FILM

Figure 49.9 shows similarly created box plots for the data in FILM after the outliers have been removed.^*

   data film;
      set film;
      if testval < 130;

   symbol v=dot c=yellow;
   title 'Variation Within Lane';
   proc shewhart data=film;
      boxchart testval*lane / boxstyle = schematicid
                              boxwidth = 5
                              idsymbol = dot
                              cframe   = vigb
                              cboxfill = vlib
                              cboxes   = yellow
                              hoffset  = 5
                              nolegend
                              stddevs
                              nolimits ;
      id sample;
   run;

Figure 49.9: The Data Set FILM Without Outliers

Since you have no additional information about the process, you may want to create a conventional $\bar{X}$ and R chart for the test values grouped by the variable SAMPLE. This is a straightforward application of the XRCHART statement in the SHEWHART procedure.

   proc sort data=film;
      by sample;

   symbol v=dot c=yellow;
   title 'Shewhart Chart for Means and Ranges';
   proc shewhart data=film;
      xrchart testval*sample /
         split     = '/'
         npanelpos = 60
         limitn    = 4
         coutfill  = red
         cframe    = vigb
         cinfill   = vlib
         cconnect  = yellow
         nolegend
         alln;
      label testval='Average Test Value/Range';
   run;

The $\bar{X}$ and R chart is displayed in Figure 49.10. Ordinarily, the out-of-control points in Figure 49.10 would indicate that the process is not in statistical control. In this situation, however, the process is known to be quite stable, and the data have been screened for outliers. Thus, the control limits seem to be inappropriate for the data.

Figure 49.10: Conventional $\bar{X}$ and R Chart

Chapter Contents
Previous
Next
Top