Chapter Contents

Previous

Next

Some Measurement Models

Psychometric test theory involves many kinds of models relating scores on psychological and educational tests to latent variables representing intelligence or various underlying abilities. The following example uses data on four vocabulary tests from Lord (1957). Tests W and X have 15 items each and are administered with very liberal time limits. Tests Y and Z have 75 items and are administered under time pressure. The covariance matrix is read by the following DATA step:

   data lord(type=cov);
      input _type_ $ _name_ $ w x y z;
      datalines;
   n   . 649       .       .       .
   cov w 86.3979   .       .       .
   cov x 57.7751 86.2632   .       .
   cov y 56.8651 59.3177 97.2850   .
   cov z 58.8986 59.6683 73.8201 97.8192
   ;

The psychometric model of interest states that W and X are determined by a single common factor F_WX, and Y and Z are determined by a single common factor F_YZ. The two common factors are expected to have a positive correlation, and it is desired to estimate this correlation. It is convenient to assume that the common factors have unit variance, so their correlation will be equal to their covariance. The error terms for all the manifest variables are assumed to be uncorrelated with each other and with the common factors. The model (labeled here as Model Form D) is as follows.

Model Form D

This path diagram can be converted to a RAM model as follows:

      /* 1=w 2=x 3=y 4=z 5=fwx 6=fyz */
   title 'H4: unconstrained';
   proc calis data=lord cov;
      ram 1 1 5 betaw,
          1 2 5 betax,
          1 3 6 betay,
          1 4 6 betaz,
          2 1 1 vew,
          2 2 2 vex,
          2 3 3 vey,
          2 4 4 vez,
          2 5 5 1,
          2 6 6 1,
          2 5 6 rho;
   run;

Here are the major results.

The same analysis can be performed with the LINEQS statement. Subsequent analyses are illustrated with the LINEQS statement rather than the RAM statement because it is slightly easier to understand the constraints as written in the LINEQS statement without constantly referring to the path diagram. The LINEQS and RAM statements may yield slightly different results due to the inexactness of the numerical optimization; the discrepancies can be reduced by specifying a more stringent convergence criterion such as GCONV=1E-4 or GCONV=1E-6. It is convenient to create an OUTRAM= data set for use in fitting other models with additional constraints.

   title 'H4: unconstrained';
   proc calis data=lord cov outram=ram4;
      lineqs w=betaw fwx + ew,
             x=betax fwx + ex,
             y=betay fyz + ey,
             z=betaz fyz + ez;
      std fwx fyz=1,
          ew ex ey ez=vew vex vey vez;
      cov fwx fyz=rho;
   run;

The LINEQS displayed output is as follows.

In an analysis of these data by Jreskog and Srbom (1979, pp. 54 -56; Loehlin 1987, pp. 84 -87), four hypotheses are considered:

The hypothesis H₃ says that there is really just one common factor instead of two; in the terminology of test theory, W, X, Y, and Z are said to be congeneric. The hypothesis H₂ says that W and X have the same true-scores and have equal error variance; such tests are said to be parallel. The hypothesis H₂ also requires Y and Z to be parallel. The hypothesis H₁ says that W and X are parallel tests, Y and Z are parallel tests, and all four tests are congeneric.

It is most convenient to fit the models in the opposite order from that in which they are numbered. The previous analysis fit the model for H₄ and created an OUTRAM= data set called ram4. The hypothesis H₃ can be fitted directly or by modifying the ram4 data set. Since H₃ differs from H₄ only in that is constrained to equal 1, the ram4 data set can be modified by finding the observation for which _NAME_='rho' and changing the variable _NAME_ to a blank value (meaning that the observation represents a constant rather than a parameter to be fitted) and setting the variable _ESTIM_ to the value 1. Both of the following analyses produce the same results:

   title 'H3: W, X, Y, and Z are congeneric';
   proc calis data=lord cov;
      lineqs w=betaw f + ew,
             x=betax f + ex,
             y=betay f + ey,
             z=betaz f + ez;
      std f=1,
          ew ex ey ez=vew vex vey vez;
   run;

   data ram3(type=ram);
      set ram4;
      if _name_='rho' then
         do;
            _name_=' ';
            _estim_=1;
         end;
   run;

   proc calis data=lord inram=ram3 cov;
   run;

The resulting output from either of these analyses is displayed in Figure 14.14.

   title 'H2: W and X parallel, Y and Z parallel';
   proc calis data=lord cov;
      lineqs w=betawx fwx + ew,
             x=betawx fwx + ex,
             y=betayz fyz + ey,
             z=betayz fyz + ez;
      std fwx fyz=1,
          ew ex ey ez=vewx vewx veyz veyz;
      cov fwx fyz=rho;
   run;

   data ram2(type=ram);
      set ram4;
      if _name_= 'betaw' then _name_='betawx';
      if _name_='betax' then _name_='betawx';
      if _name_='betay' then _name_='betayz';
      if _name_='betaz' then _name_='betayz';
      if _name_='vew' then _name_='vewx';



      if _name_='vex' then _name_='vewx';
      if _name_='vey' then _name_='veyz';
      if _name_='vez' then _name_='veyz';
   run;

   proc calis data=lord inram=ram2 cov;
   run;

The resulting output from either of these analyses is displayed in Figure 14.15.

   title 'H1: W and X parallel, Y and Z parallel, all congeneric';
   proc calis data=lord cov;
      lineqs w=betawx f + ew,
             x=betawx f + ex,
             y=betayz f + ey,
             z=betayz f + ez;
      std f=1,
          ew ex ey ez=vewx vewx veyz veyz;
   run;

   data ram1(type=ram);
      set ram2;
      if _name_='rho' then
         do;
            _name_=' ';
            _estim_=1;
         end;
   run;

   proc calis data=lord inram=ram1 cov;
   run;

The resulting output from either of these analyses is displayed in Figure 14.16.

	Number of		Degrees of
Hypothesis	Parameters		Freedom	p-value
H1	4	37.33	6	0.0000	1.0
H2	5	1.93	5	0.8583	0.8986
H3	8	36.21	2	0.0000	1.0
H4	9	0.70	1	0.4018	0.8986

The hypotheses H₁ and H₃, which posit , can be rejected. Hypotheses H₂ and H₄ seem to be consistent with the available data. Since H₂ is obtained by adding four constraints to H₄, you can test H₂ versus H₄ by computing the differences of the chi-square statistics and their degrees of freedom, yielding a chi-square of 1.23 with four degrees of freedom, which is obviously not significant. So hypothesis H₂ is consistent with the available data.

The estimates of for H₂ and H₄ are almost identical, about 0.90, indicating that the speeded and unspeeded tests are measuring almost the same latent variable, even though the hypotheses that stated they measured exactly the same latent variable are rejected.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.