Chapter Contents

Previous

Next

Example 29.7: Log-Linear Model for Count Data

Model the data as a log-linear model with (the Poisson variance function) and

• Y_ij= number of epileptic seizures in interval j
• t_ij= length of interval j
• 
• 

The correlations between the counts are modeled as , (exchangeable correlations). For comparison, the correlations are also modeled as independent (identity correlation matrix). In this model, the regression parameters have the interpretation in terms of the log seizure rate displayed in Table 29.6.

Table 29.6: Interpretation of Regression Parameters

Treatment	Visit	log(E(Yij)/tij)
Placebo	Baseline
	1-4
Progabide	Baseline
	1-4

The difference between the log seizure rates in the pretreatment (baseline) period and the treatment periods is for the placebo group and for the Progabide group. A value of indicates a reduction in the seizure rate.

The following statements input the data, which are arranged as one visit per observation:

   data thall;
      input id y visit trt bline age;
   datalines;
   104 5 1  0 11 31
   104 3 2  0 11 31
   104 3 3  0 11 31
   104 3 4  0 11 31
   106 3 1  0 11 30
   106 5 2  0 11 30
   106 3 3  0 11 30
   106 3 4  0 11 30
   107 2 1  0 6 25
   107 4 2  0 6 25
   107 0 3  0 6 25
   107 5 4  0 6 25
   114 4 1  0 8 36
   114 4 2  0 8 36
   ...
   run;

Some further data manipulations create an observation for the baseline measures, a log time interval variable for use as an offset, and an indicator variable for whether the observation is for a baseline measurement or a visit measurement. Patient 207 is deleted as an outlier, as in the Diggle, Liang, and Zeger (1994) analysis.

   data new;
      set thall;
      output;
      if visit=1 then do;
         y=bline;
         visit=0;
         output;
      end;
   run;

   data new2;
      set new;
      if id ne 207;
      if visit=0 then do;
         x1=0;
         ltime=log(8);
      end;
      else do;
         x1=1;
         ltime=log(2);
      end;
   run;

The GEE solution is requested by using the REPEATED statement in the GENMOD procedure. The SUBJECT=ID option indicates that the id variable describes the observations for a single cluster, and the CORRW option displays the working correlation matrix. The TYPE= option specifies the correlation structure; the value EXCH indicates the exchangeable structure.

   proc genmod data=new2;
      class id;
      model y=x1 | trt / d=poisson offset=ltime;
      repeated subject=id / corrw covb type=exch;
   run;

These statements first produce the usual output from fitting a generalized linear model (GLM) to these data. The estimates are used as initial values for the GEE solution.

Information about the GEE model is displayed in Output 29.7.2. The results of fitting the model are displayed in Output 29.7.3. Compare these with the model of independence displayed in Output 29.7.1. The parameter estimates are nearly identical, but the standard errors for the independence case are underestimated. The coefficient of the interaction term, , is highly significant under the independence model and marginally significant with the exchangeable correlations model.

The fitted exchangeable correlation matrix is specified with the CORRW option and is displayed in Output 29.7.4.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.