Chapter Contents

Previous

Next

Example 49.6: Survivor Function Estimates for Specific Covariate Values

You may want to use your regression analysis results to generate predicted survival curves for subjects not in the study. This example illustrates how to use the BASELINE statement to obtain the survivor function for a new set of explanatory variable values. The various sets of explanatory variable values must be contained in a SAS data set.

In previous examples, LogBUN and HGB were identified as the most important prognostic factors for the myeloma data. Suppose you are interested in obtaining the survivor function estimates for the following two realizations of LogBUN and HGB, which are saved in a SAS data set called Inrisks.

   data Inrisks;
      input LogBUN HGB;
      datalines;
   1.00 10.0
   1.80 12.0
   ;

In the BASELINE statement, you specify the name of the data set (COVARIATE=Inrisk) that contains the various sets of explanatory variable values and the name of the output SAS data set (OUT=Pred1) that contains the survivor function estimates. The option SURVIVAL=S puts the variable S containing the survivor function estimates in the output data set Pred1. Similarly, the options LOWER=S_lower and UPPER=S_upper put the variables S_lower and S_upper in Pred1; these variables contain, respectively, the lower and upper 95% confidence limits for the survival. The NOPRINT option in the PROC PHREG statement suppresses the displayed output (the analysis results are shown in Example 49.1). The PRINT procedure displays the observations in the data set Pred1.

   proc phreg data=Myeloma noprint;
      model Time*VStatus(0)=LogBUN HGB;
      baseline covariates=Inrisks out=Pred1 survival=S
               lower=S_lower upper=S_upper;
   run;
   proc print data=Pred1;
   run;

By default, the procedure also outputs the set of survivor function estimates for LogBUN=1.3929 and HGB=10.2015, which are the sample means of LogBUN and HGB for the input data in Myeloma. (Note that in a stratified analysis, the sample means are calculated within each stratum.) The estimated survivor function estimates for these sample means are the last 32 observations in the data set Pred1. You can suppress this set of survival estimates by using the NOMEAN option in the BASELINE statement.

   proc phreg data=Myeloma noprint;
      model Time*VStatus(0)=LogBUN HGB;
      baseline covariates=Inrisks out=Pred2 survival=S
               lower=S_lower upper=S_upper / nomean;
   run;

The data set Pred2 consists of the first 64 observations of Pred1. If you are interested only in the survivor function estimates for the sample means of the explanatory variables, you can omit the COVARIATES= option in the BASELINE statement.

   proc phreg data=Myeloma noprint;
      model Time*VStatus(0)=LogBUN HGB;
      baseline out=Pred3 survival=S lower=S_lower upper=S_upper;
   run;

The data set Pred3 contains the last 32 observations of Pred1.

The following SAS statements are used to plot the survival curves in Pred1. For convenience, the variable Pattern is added to the data set Pred1 to identify the various patterns of explanatory variables.

   data Pred1;
      set Pred1;
      if      LogBUN= 1.0 and HGB=10.0 then Pattern=1;
      else if LogBUN= 1.8 and HGB=12.0 then Pattern=2;
      else                                  Pattern=3;

   legend1 label=none shape=symbol(3, .8)
      value=(f=swiss h=.8 'LogBUN=1.00 HGB=10.0'
             'LogBUN=1.80  HGB=12.0' 'LogBUN=1.39 HGB=10.2');
   axis1 label=(h=1 f=swiss a=90) minor=(n=1);
   axis2 label=(h=1 f=swiss 'Survival Time in Months') minor=(n=4);

   proc gplot data=Pred1;
      plot S*Time=Pattern / legend=legend1 vaxis=axis1 
                            haxis=axis2    cframe=ligr;
      symbol1 interpol=stepLJ h=1 v=square  c=blue;
      symbol2 interpol=stepLJ h=1 v=diamond c=yellow;
      symbol3 interpol=stepLJ h=1 v=circle  c=red;
      note f=swiss h=1.5 j=c 'Myeloma Study';
      footnote h=.8 f=duplex
         'LogBUN=1.39 and HGB=10.2 correspond to the sample means';
   run;

The survivor function estimates for these three patterns of explanatory variables are displayed in Output 49.6.2. Note that these survivor functions are portrayed as right-continuous functions.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.