Chapter Contents
Previous
Next
|
Chapter Contents |
Previous |
Next |
| The PRINQUAL Procedure |
The data are ratings by 25 judges of their preference for each of 17 automobiles. The ratings are made on a 0 to 9 scale, with 0 meaning very weak preference and 9 meaning very strong preference for the automobile. These judgments were made in 1980 about that year's products. There are two additional variables that indicate the manufacturer and model of the automobile.
This example uses PROC PRINQUAL, PROC FACTOR, and the %PLOTIT macro. PROC FACTOR is used before PROC PRINQUAL to perform a principal component analysis of the raw judgments. PROC FACTOR is also used immediately after PROC PRINQUAL since PROC PRINQUAL is a scoring procedure that optimally scores the data but does not report the principal component analysis.
The %PLOTIT macro produces the biplot. For information on the %PLOTIT macro, see Appendix B, "Using the %PLOTIT Macro."
The scree plot, in the standard principal component analysis reported by PROC FACTOR, shows that two principal components should be retained for further use. (See the scree plot in Output 53.1.1 -there is a clear separation between the first two components and the remaining components.) There are nine eigenvalues that are precisely zero because there are nine fewer observations than variables in the data matrix. PROC PRINQUAL is then used to monotonically transform the raw judgments to maximize the proportion of variance accounted for by the first two principal components. The following statements create the data set and perform a principal component analysis of the original data. These statements produce Output 53.1.1.
title 'Preference Ratings for Automobiles Manufactured in 1980';
data CarPref;
input Make $ 1-10 Model $ 12-22 @25 (Judge1-Judge25) (1.);
datalines;
Cadillac Eldorado 8007990491240508971093809
Chevrolet Chevette 0051200423451043003515698
Chevrolet Citation 4053305814161643544747795
Chevrolet Malibu 6027400723121345545668658
Ford Fairmont 2024006715021443530648655
Ford Mustang 5007197705021101850657555
Ford Pinto 0021000303030201500514078
Honda Accord 5956897609699952998975078
Honda Civic 4836709507488852567765075
Lincoln Continental 7008990592230409962091909
Plymouth Gran Fury 7006000434101107333458708
Plymouth Horizon 3005005635461302444675655
Plymouth Volare 4005003614021602754476555
Pontiac Firebird 0107895613201206958265907
Volkswagen Dasher 4858696508877795377895000
Volkswagen Rabbit 4858509709695795487885000
Volvo DL 9989998909999987989919000
;
* Principal Component Analysis of the Original Data;
options ls=80 ps=65;
proc factor data=CarPref nfactors=2 scree;
ods select Eigenvalues ScreePlot;
var Judge1-Judge25;
title3 'Principal Components of Original Data';
run;
Output 53.1.1: Principal Component Analysis of Original Data
is the principal component model, where
.The W and 
contain the eigenvectors and eigenvalues of
the correlation matrix of X.
The first two columns of V, the standardized
component scores, and 
,which is the structure matrix, are output.
The advantage of creating a biplot based on
principal components is
that coordinates do not depend on the sample size.
The following statements transform the
data and produce Output 53.1.2.
* Transform the Data to Better Fit a Two Component Model;
proc prinqual data=CarPref out=Results n=2 replace mdpref;
id model;
transform monotone(Judge1-Judge25);
title2 'Multidimensional Preference (MDPREF) Analysis';
title3 'Optimal Monotonic Transformation of Preference Data';
run;
Output 53.1.2: Transformation of Automobile Preference Data|
| |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
The second PROC FACTOR analysis is performed on the transformed data. The WHERE statement is used to retain only the monotonically transformed judgments. The scree plot shows that the first two eigenvalues are now much larger than the remaining smaller eigenvalues. The second eigenvalue has increased markedly at the expense of the next several eigenvalues. Two principal components seem to be necessary and sufficient to adequately describe these judges' preferences for these automobiles. The cumulative proportion of variance displayed by PROC FACTOR for the first two principal components is 0.83. The following statements perform the analysis and produce Output 53.1.3:
* Final Principal Component Analysis;
proc factor data=Results nfactors=2 scree;
ods select Eigenvalues ScreePlot;
var Judge1-Judge25;
where _TYPE_='SCORE';
title3 'Principal Components of Monotonically Transformed Data';
run;
Output 53.1.3: Principal Components of Transformed Data|
| |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
, which is the structure matrix,
contain enough information to reproduce X.
The (i,j) element of X is the product of
row i of V and row j of .If all but the first two columns of V and
are discarded, the (i,j) element
of X is approximated by the product of row i
of V and row j of .Since the MDPREF analysis is based on a principal component model, the dimensions of the MDPREF biplot are the first two principal components. The first principal component is the longest dimension through the MDPREF biplot. The first principal component is overall preference, which is the most salient dimension in the preference judgments. One end points in the direction that is on the average preferred most by the judges, and the other end points in the least preferred direction. The second principal component is orthogonal to the first principal component, and it is the orthogonal direction that is the second most salient. The interpretation of the second dimension varies from example to example.
With an MDPREF biplot, it is geometrically appropriate to represent each automobile (object) by a point and each judge by a vector. The automobile points have coordinates that are the scores of the automobile on the first two principal components. The judge vectors emanate from the origin of the space and go through a point with coordinates that are the coefficients of the judge (variable) on the first two principal components.
The absolute length of a vector is arbitrary.
However, the relative lengths of the vectors indicate
fit, with the squared lengths being proportional
to the communalities in the PROC FACTOR output.
The direction of the vector indicates the direction
that is most preferred by the individual judge, with
preference increasing as the vector moves from the origin.
Let v' be row i of V,
u'
be row j of 
,|v| be
the length of v, |u| be the length of u,
and 
be the angle between v and u.
The predicted degree of preference that an
individual judge has for an automobile is
.Each car point can be orthogonally
projected onto the vector.
The projection of car i on vector j is
u((u'v)/(u'u))
and the length of this projection is 
.The automobile that projects farthest along a vector
in the direction it points is that judge's most preferred
automobile, since the length of this projection, , differs from the predicted preference,
, only by
|u|, which is constant within each judge.
To interpret the biplot, look for directions through the plot that show a continuous change in some attribute of the automobiles, or look for regions in the plot that contain clusters of automobile points and determine what attributes the automobiles have in common. Those points that are tightly clustered in a region of the plot represent automobiles that have the same preference patterns across the judges. Those vectors that point in roughly the same direction represent judges who tend to have similar preference patterns.
The following statement constructs the biplot and produces
Output 53.1.4:
title3 'Biplot of Automobiles and Judges'; %plotit(data=results, datatype=mdpref 2);
The DATATYPE=MDPREF 2 option indicates that the coordinates come from an MDPREF analysis, so the macro represents the scores as points and the structure as vectors, with the vectors stretched by a factor of two to make a better graphical display.
Output 53.1.4: Preference Ratings for Automobiles Manufactured in 1980
|
The two expensive American automobiles form a cluster, the sporty automobile (Firebird) is by itself, the Volvo DL is by itself, and the remaining imported autos form a cluster, as do the remaining American autos. It seems there are 5 prototypical automobiles in this set of 17, in terms of preference patterns among the 25 judges.
Most of the judges prefer the imported automobiles, especially the Volvo. There is also a fairly large minority that prefer the expensive cars, whether or not they are American (those with vectors that point towards one o'clock), or simply prefer expensive American automobiles (vectors that point towards eleven o'clock). There are two people who prefer anything except expensive American cars (five o'clock vectors), and one who prefers inexpensive American cars (seven o'clock vector).
Several vectors point toward the upper-right corner of the plot, toward a region with no cars. This is the region between the European and Japanese cars on the right and the luxury cars on the top. This suggests that there is a market for luxury Japanese and European cars.
|
Chapter Contents |
Previous |
Next |
 Top |
Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.