Chapter Contents

Previous

Next

Example 59.1: Standardization of Variables in Cluster Analysis

The species (Bream, Parkki, Pike, Perch, Roach, Smelt, and Whitefish), weight, three different length measurements (measured from the nose of the fish to the beginning of its tail, the notch of its tail, and the end of its tail), height, and width of each fish are recorded. The height and width are recorded as percentages of the third length variable.

Several new variables are created in the Fish data set: Weight3, Height, Width, and logLengthRatio. The weight of a fish indicates its size -a heavier Tuna tends to be larger than a lighter Tuna. To get a one dimensional measure of the size of a fish, take the cubic root of the weight (Weight3). The variables Height, Width, Length1, Length2, and Length3 are rescaled in order to adjust for dimensionality. The logLengthRatio variable measures the tail length.

Because the new variables Weight3 -logLengthRatio depend on the variable Weight, observations with missing values for Weight are not added to the data set. Consequently, there are 157 observations in the SAS data set Fish.

Before you perform a cluster analysis on coordinate data, it is necessary to consider scaling or transforming the variables since variables with large variances tend to have a larger effect on the resulting clusters than those with small variances.

This example uses three different approaches to standardize or transform the data prior to the cluster analysis. The first approach uses several standardization methods provided in the STDIZE procedure. However, since standardization is not always appropriate prior to the clustering (refer to Milligan and Cooper, 1987, for a Monte Carlo study on various methods of variable standardization), the second approach performs the cluster analysis with no standardization. The third approach invokes the ACECLUS procedure to transform the data into a within-cluster covariance matrix.

The clustering is performed by the FASTCLUS procedure to find seven clusters. Note that the variables Length2 and Length3 are eliminated from this analysis since they both are significantly and highly correlated with the variable Length1. The correlation coefficients are 0.9958 and 0.9604, respectively. An output data set is created, and the FREQ procedure is invoked to compare the clusters with the species classification.

The DATA step is as follows:

   proc format;
      value specfmt
         1='Bream'
         2='Roach'
         3='Whitefish'
         4='Parkki'
         5='Perch'
         6='Pike'
         7='Smelt';
   data Fish (drop=HtPct WidthPct);
      title 'Fish Measurement Data';
      input Species Weight Length1 Length2 Length3 HtPct 
            WidthPct @@;

      if Weight <= 0 or Weight=. then delete;
      Weight3=Weight**(1/3);
      Height=HtPct*Length3/(Weight3*100);
      Width=WidthPct*Length3/(Weight3*100);
      Length1=Length1/Weight3; 
      Length2=Length2/Weight3; 
      Length3=Length3/Weight3;
      logLengthRatio=log(Length3/Length1);

      format Species specfmt.;
      symbol = put(Species, specfmt2.);
      datalines;
   1  242.0 23.2 25.4 30.0 38.4 13.4
   1  290.0 24.0 26.3 31.2 40.0 13.8 
   1  340.0 23.9 26.5 31.1 39.8 15.1
   1  363.0 26.3 29.0 33.5 38.0 13.3 
   ... [155 more records] 
   ;
   run;

The following macro, Std, standardizes the Fish data. The macro reads a single argument, mtd, which selects the METHOD= specification to be used in PROC STDIZE.

   /*--- macro for standardization ---*/

   %macro Std(mtd);
   title2 "Data is standardized by PROC STDIZE with 
           METHOD= &mtd";
      proc stdize data=fish out=sdzout method=&mtd;
         var Length1 logLengthRatio Height Width Weight3;
      run;
   %mend Std;

The following macro, FastFreq, includes a PROC FASTCLUS statement for performing cluster analysis and a PROC FREQ statement for cross-tabulating species with the cluster membership information that is derived from the previous PROC FASTCLUS statement. The macro reads a single argument, ds, which selects the input data set to be used in PROC FASTCLUS.

   /*--- macro for clustering and cross-tabulating ---*/
   /*--- cluster membership with species           ---*/
   %macro FastFreq(ds);
      proc fastclus data=&ds out=clust maxclusters=7 maxiter=100 noprint;
         var Length1 logLengthRatio Height Width Weight3;
      run;

      proc freq data=clust;
         tables species*cluster;
      run;
   %mend FastFreq;

The following analysis, (labeled `Approach 1') includes 18 different methods of standardization followed by clustering. Since there is a large amount of output from this approach, only results from METHOD=STD, METHOD=RANGE, METHOD=AGK(.14), and METHOD=SPACING(.14) are shown. The following statements produce Output 59.1.1 through Output 59.1.4.

   /**********************************************************/
   /*                                                        */
   /*     Approach 1: data is standardized by PROC STDIZE    */
   /*                                                        */
   /**********************************************************/

   %Std(MEAN);                  
   %FastFreq(sdzout);           
                                
   %Std(MEDIAN);                
   %FastFreq(sdzout);           
                                
   %Std(SUM);                   
   %FastFreq(sdzout);           
                                
   %Std(EUCLEN);                
   %FastFreq(sdzout);           
                                
   %Std(USTD);                  
   %FastFreq(sdzout);           
                                
   %Std(STD);                   
   %FastFreq(sdzout);           
                                
   %Std(RANGE);                 
   %FastFreq(sdzout);           
                                
   %Std(MIDRANGE);              
   %FastFreq(sdzout);           
                                
   %Std(MAXABS);                
   %FastFreq(sdzout);           
                                
   %Std(IQR);                   
   %FastFreq(sdzout);           
                                
   %Std(MAD);                   
   %FastFreq(sdzout);           
                                
   %Std(AGK(.14));              
   %FastFreq(sdzout);           
                                
   %Std(SPACING(.14));          
   %FastFreq(sdzout);           
                                
   %Std(ABW(5));                
   %FastFreq(sdzout);           
                                
   %Std(AWAVE(5));              
   %FastFreq(sdzout);           
                                
   %Std(L(1));                  
   %FastFreq(sdzout);           
                                
   %Std(L(1.5));                
   %FastFreq(sdzout);           
                                
   %Std(L(2));                  
   %FastFreq(sdzout);           

   /**********************************************************/
   /*                                                        */
   /*         Approach 2: data is untransformed              */
   /*                                                        */
   /**********************************************************/

   title2 'Data is untransformed';
   %FastFreq(fish);

   /**********************************************************/
   /*                                                        */
   /*    Approach 3: data is transformed by PROC ACECLUS     */
   /*                                                        */
   /**********************************************************/

   title2 'Data is transformed by PROC ACECLUS';
   proc aceclus data=fish out=ace p=.02 noprint;
      var Length1 logLengthRatio Height Width Weight3;
   run;
   %FastFreq(ace);

Consider the results displayed in Output 59.1.1. In that analysis, the method of standardization is STD, and the number of clusters and the number of misclassifications are computed as shown in Table 59.5.

In Output 59.1.1, the Bream species is classified as cluster 6 since all 34 Bream fish are categorized into cluster 6 with no misclassification. A similar pattern is seen with the Roach, Parkki, Pike, and Smelt species.

For the Whitefish species, two fish are categorized into cluster 2, one fish is categorized into cluster 4, and three fish are categorized into cluster 7. Because the majority of this species is categorized into cluster 7, it is recorded in Table 59.5 as being classified as cluster 7 with 3 misclassifications. A similar pattern is seen with the Perch species: it is classified as cluster 7 with 29 misclassifications.

In summary, when the standardization method is STD, seven species of fish are classified into only 5 clusters and the total number of misclassified observations is 33.

The result of this analysis demonstrates that when variables are standardized by the STDIZE procedure with methods including RANGE, MIDRANGE, MAXABS, AGK(.14), and SPACING(.14), the FASTCLUS procedure produces the correct number of clusters and less misclassification than it does when other standardization methods are used. The SPACING method attains the best result, probably because the variables Length1 and Height both exhibit marked groupings (bimodality) in their distributions.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.