Chapter Contents

Previous

Next

Using the DESIGN Output Option

This example uses PROC TRANSREG and the DESIGN o-option to prepare an input data set with classification variables for the LOGISTIC procedure. The DESIGN o-option specifies that the goal is design matrix creation, not analysis. When you specify DESIGN, dependent variables are not required. The DEVIATIONS (or EFFECTS) t-option requests a deviations-from-means (1, 0, -1) coding of the classification variables, which is the same coding the CATMOD procedure uses. See Figure 65.29. PROC TRANSREG automatically creates a macro variable &_trgind that contains the list of independent variables created. This macro is used in the PROC LOGISTIC MODEL statement. See Figure 65.30. For comparison, the same analysis is also performed with PROC CATMOD. See Figure 65.31.

   title 'Using PROC TRANSREG to Create a Design Matrix';

   data a;
      do y = 1, 2;
         do a = 1 to 4;
            do b = 1 to 3;
               w = ceil(uniform(1) * 10 + 10);
               output;
            end;
         end;
      end;
   run;

   proc transreg data=a design;
      model class(a b / deviations);
      id y w;
      output;
   run;

   proc print;
      title2 'PROC TRANSREG Output Data Set';
   run;

   proc logistic;
      title2 'PROC LOGISTIC with Classification Variables';
      freq w;
      model y = &_trgind;
   run;

   proc catmod data=a;
      title2 'PROC CATMOD Should Produce the Same Results';
      model y = a b;
      weight w;
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.