Chapter Contents

Previous

Next

Example 68.1: Correlations among Physical Variables

The following data are correlations among eight physical variables as given by Harman (1976). The first PROC VARCLUS run clusters on the basis of principal components, the second run clusters on the basis of centroid components. The third analysis is hierarchical, and the TREE procedure is used to print a tree diagram. The results of the analyses follow.

   data phys8(type=corr);
      title 'Eight Physical Measurements on 305 School Girls';
      title2 'Harman: Modern Factor Analysis, 3rd Ed, p22';
      label height='Height'
            arm_span='Arm Span'
            forearm='Length of Forearm'
            low_leg='Length of Lower Leg'
            weight='Weight'
            bit_diam='Bitrochanteric Diameter'
            girth='Chest Girth'
            width='Chest Width';

      input _name_ $ 1-8
            (height arm_span forearm low_leg weight bit_diam 
             girth width)(7.);
      _type_='corr';
      datalines;
   height  1.0    .846   .805   .859   .473   .398   .301   .382
   arm_span.846   1.0    .881   .826   .376   .326   .277   .415
   forearm .805   .881   1.0    .801   .380   .319   .237   .345
   low_leg .859   .826   .801   1.0    .436   .329   .327   .365
   weight  .473   .376   .380   .436   1.0    .762   .730   .629
   bit_diam.398   .326   .319   .329   .762   1.0    .583   .577
   girth   .301   .277   .237   .327   .730   .583   1.0    .539
   width   .382   .415   .345   .365   .629   .577   .539   1.0
   ;

   proc varclus data=phys8;
   run;

The PROC VARCLUS statement invokes the procedure. By default, PROC VARCLUS clusters on the basis of principal components.

The cluster is split because the second eigenvalue is greater than 1 (the default value of the MAXEIGEN option).

The two resulting cluster components explain 80.33% of the variation in the original variables. The cluster summary table shows that the variables height, arm_span, forearm, and low_leg have been assigned to the first cluster; and that the variables weight, bit_diam, girth, and width have been assigned to the second cluster.

The cluster structure table displays high correlations between the variables and their own cluster component. The correlations between the variables and the opposite cluster component are all moderate.

In the following statements, the CENTROID option in the PROC VARCLUS statement specifies that cluster centroids be used as the basis for clustering.

   proc varclus data=phys8 centroid;
   run;

The centroid clustering algorithm splits the variables into the same two clusters created in the principal component method. Recall that this outcome was suggested by the similar standardized scoring coefficients in the principal cluster component solution.

The default behavior in the centroid method is to split any cluster with less than 75% of the total cluster variance explained by the centroid component. In the next step, the second cluster, with a component that explains only 72.75% of the total variation of the cluster, is split.

In the R-squared table for two clusters, the width variable has a weaker relation to its cluster than any other variable; in the three cluster solution this variable is in a cluster of its own.

In the following statements, the MAXC= option computes all clustering solutions, from one to eight clusters. The SUMMARY option suppresses all output except the final cluster quality table, and the OUTTREE= option saves the results of the analysis to an output data set and forces the clusters to be hierarchical. The TREE procedure is invoked to produce a graphical display of the clusters.

   proc varclus data=phys8 maxc=8 summary outtree=tree;
   run;

   goptions ftext=swiss; 
   axis2 minor=none;
   axis1 label=('Proportion of Variation Explained') minor=none;
   proc tree horizontal vaxis=axis2 haxis=axis1 lines=(width=2);
      height _propor_;
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.