Sample Variogram Computation and Plots

The VARIOGRAM Procedure

Sample Variogram Computation and Plots

Using the values of LAGDISTANCE=7.0 and MAXLAGS=10 computed previously, rerun PROC VARIOGRAM without the NOVARIOGRAM option. Also, request a robust version of the semivariogram; then, plot both results against the pairwise distance of each class.

   proc variogram data=thick outv=outv;
      compute lagd=7 maxlag=10 robust;
      coordinates xc=east yc=north;
      var thick;
   run;

   title 'OUTVAR= Data Set Showing Sample Variogram Results';
   proc print data=outv label;
      var lag count distance variog rvario;
   run;

   data outv2; set outv;
      vari=variog; type = 'regular'; output;
      vari=rvario; type = 'robust'; output;
   run;

   title 'Standard and Robust Semivariogram for Coal Seam 
          Thickness Data';
   proc gplot data=outv2;
      plot vari*distance=type / frame cframe=ligr vaxis=axis2 
                                haxis=axis1;
      symbol1 i=join l=1 c=blue   /* v=star   */;
      symbol2 i=join l=1 c=yellow /* v=square */;
      axis1 minor=none 
            label=(c=black 'Lag Distance') /* offset=(3,3) */;
      axis2 order=(0 to 9 by 1) minor=none 
            label=(angle=90 rotate=0 c=black 'Variogram') 
            /* offset=(3,3) */;
   run;

OUTVAR= Data Set Showing Sample Variogram Results

Obs	Lag Class Value (in LAGDIST= units)	Number of Pairs in Class	Average Lag Distance for Class	Variogram	Robust Variogram
1	-1	75	.	.	.
2	0	8	2.5045	0.02937	0.01694
3	1	85	7.3625	0.38047	0.19807
4	2	142	14.1547	1.15158	0.98029
5	3	169	21.0913	2.79719	3.01412
6	4	199	27.9691	4.68769	4.86998
7	5	199	35.1591	6.16018	6.15639
8	6	205	42.2547	7.58912	8.05072
9	7	232	48.7775	7.12506	7.07155
10	8	244	56.1824	7.04832	7.62851
11	9	285	62.9121	6.66298	8.02993
12	10	262	69.8925	6.18775	7.92206

Figure 70.7: OUTVAR= Data Set Showing Sample Variogram Results

Figure 70.8: Standard and Robust Semivariogram for Coal Seam Thickness Data

Figure 70.8 shows first a slow, then a rapid rise from the origin, suggesting a Gaussian type form:

$\gamma_z(h)=c_0[1-\exp(-\frac{h^2}{a_0^2})]$

See the section "Theoretical and Computational Details of the Semivariogram" for graphs of the standard semivariogram forms.

By experimentation, you find that a scale of c₀=7.5 and a range of a₀=30 fits reasonably well for both the robust and standard semivariogram

The following statements plot the sample and theoretical variograms:

   data outv3; set outv;
      c0=7.5; a0=30;
      vari = c0*(1-exp(-distance*distance/(a0*a0)));
      type = 'Gaussian'; output;
      vari = variog; type = 'regular'; output;
      vari = rvario; type = 'robust'; output;
   run;
   
   title 'Theoretical and Sample Semivariogram for Coal Seam 
          Thickness Data';
   proc gplot data=outv3;
      plot vari*distance=type / frame cframe=ligr vaxis=axis2 
                                haxis=axis1;
      symbol1 i=join l=1 c=blue    /* v=star    */;
      symbol2 i=join l=1 c=yellow  /* v=square  */;
      symbol3 i=join l=1 c=cyan    /* v=diamond */;
      axis1 minor=none 
            label=(c=black 'Lag Distance') /* offset=(3,3) */;
      axis2 order=(0 to 9 by 1) minor=none 
            label=(angle=90 rotate=0 c=black 'Variogram') 
            /* offset=(3,3) */; 
   run;

Figure 70.9: Theoretical and Sample Semivariogram for Coal Seam Thickness Data

Figure 70.9 shows that the choice of a semivariogram model is adequate. You can use this Gaussian form and these particular parameters in PROC KRIGE2D to produce a contour plot of the kriging estimates and the associated standard errors.

Chapter Contents
Previous
Next
Top