Example 14.10: Systems of Differential Equations

The MODEL Procedure

Example 14.10: Systems of Differential Equations

The following is a simplified reaction scheme for the competitive inhibitors with recombinant human renin (Morelock et al. 1995).

Figure 14.82: Competitive Inhibition of Recombinant Human Renin

In Figure 14.82, E= enzyme, D= probe, and I= inhibitor.

The differential equations describing this reaction scheme are

$\frac{d{D}}{dt} = k1r{\ast}{ED} - k1f {\ast}E{\ast}D$

$\frac{d{ED}}{dt} = k1f{\ast} E{\ast}D - k1r{\ast}{ED}$

$\frac{d{E}}{dt} = k1r{\ast} {ED} - k1f{\ast} E {\ast} D + k2r {\ast} {EI} - k2f {\ast} E {\ast}I$

$\frac{d{EI}}{dt} = k2f{\ast} E {\ast}I - k2r {\ast} {EI}$

$\frac{d{I}}{dt} = k2r{\ast} {EI} - k2f {\ast} E {\ast} I$

For this system, the initial values for the concentrations are derived from equilibrium considerations (as a function of parameters) or are provided as known values.

The experiment used to collect the data was carried out in two ways; pre-incubation (type='disassoc') and no pre-incubation (type='assoc'). The data also contain repeated measurements. The data contain values for fluorescence F, which is a function of concentration. Since there are no direct data for the concentrations, all the differential equations are simulated dynamically.

The SAS statements used to fit this model are

      proc model data=fit;
   
         parameters qf  = 2.1e8
                    qb  = 4.0e9
                    k2f = 1.8e5
                    k2r = 2.1e-3
                    l   = 0;
   
                    k1f = 6.85e6;
                    k1r = 3.43e-4;
   
            /* Initial values for concentrations */
         control dt 5.0e-7
                 et 5.0e-8
                 it 8.05e-6;
   
            /* Association initial values --------------*/
         if type = 'assoc' and time=0 then 
            do;
               ed = 0;
                  /* solve quadratic equation ----------*/
               a = 1;
               b = -(&it+&et+(k2r/k2f));
               c = &it*&et;
               ei = (-b-(((b**2)-(4*a*c))**.5))/(2*a);
               d = &dt-ed;
               i = &it-ei;
               e = &et-ed-ei;
            end;
   
            /* Disassociation initial values ----------*/
         if type = 'disassoc' and time=0 then 
            do;
               ei = 0;
               a = 1;
               b = -(&dt+&et+(&k1r/&k1f));
               c = &dt*&et;
               ed = (-b-(((b**2)-(4*a*c))**.5))/(2*a);
               d = &dt-ed;
               i = &it-ei;
               e = &et-ed-ei;
            end;
   
         if time ne 0 then 
            do;
               dert.d = k1r* ed  - k1f *e *d;
      
               dert.ed = k1f* e *d - k1r*ed;
   
               dert.e = k1r* ed - k1f* e * d  + k2r * ei - k2f * e *i;
   
               dert.ei = k2f* e *i - k2r * ei;
   
               dert.i = k2r * ei - k2f* e *i;
   
            end;
   
            /* L - offset between curves  */
         if type = 'disassoc' then
                 F = (qf*(d-ed)) + (qb*ed) -L; 
         else
                 F = (qf*(d-ed)) + (qb*ed);
   
         Fit F / method=marquardt;
      run;

This estimation requires the repeated simulation of a system of 42 differential equations (5 base differential equations and 36 differential equations to compute the partials with respect to the parameters).

The results of the estimation are shown in Output 14.10.1.

Output 14.10.1: Kinetics Estimation

The MODEL Procedure

Nonlinear OLS Parameter Estimates
Parameter	Estimate	Approx Std Err	t Value	Approx Pr > \|t\|
qf	2.0413E8	681443	299.55	<.0001
qb	4.2263E9	9133179	462.74	<.0001
k2f	6451229	867011	7.44	<.0001
k2r	0.007808	0.00103	7.55	<.0001
l	-5.76981	0.4138	-13.94	<.0001

Chapter Contents
Previous
Next
Top