Example 21.1: Component Estimation

The X11 Procedure

Example 21.1: Component Estimation - Monthly Data

This example computes and plots the final estimates of the individual components for a monthly series. In the first plot, Output 21.1.1 an overlaid plot of the original and seasonally adjusted data is produced. The trend in the data is more evident in the seasonally adjusted data than in the original data. This trend is even more clear in Output 21.1.3, the plot of Table D12, the trend cycle. Note that both the seasonal factors and the irregular factors vary around 100, while the trend cycle and the seasonally adjusted data are in the scale of the original data.

From Output 21.1.2 the seasonal component appears to be slowly increasing, while no apparent pattern exists for the irregular series in Output 21.1.4.

   data sales;
      input sales @@;
      date = intnx( 'month', '01sep1978'd, _n_-1 );
      format date monyy7.;
      datalines;
   112 118 132 129 121 135 148 148 136 119 104 118
   115 126 141 135 125 149 170 170 158 133 114 140
   145 150 178 163 172 178 199 199 184 162 146 166
   171 180 193 181 183 218 230 242 209 191 172 194
   196 196 236 235 229 243 264 272 237 211 180 201
   204 188 235 227 234 264 302 293 259 229 203 229
   242 233 267 269 270 315 364 347 312 274 237 278
   284 277 317 313 318 374 413 405 355 306 271 306
   315 301 356 348 355 422 465 467 404 347 305 336
   340 318 362 348 363 435 491 505 404 359 310 337
   360 342 406 396 420 472 548 559 463 407 362 405
   417 391 419 461 472 535 622 606 508 461 390 432
   run;
   
   proc x11 data=sales noprint;
      monthly date=date;
      var sales;
      tables b1 d11;
      output out=out b1=series d10=d10 d11=d11
                     d12=d12 d13=d13;
   run;
   
   symbol1 i=join v='star';
   symbol2 i=join v='circle';
   legend1 label=none value=('original' 'adjusted');
   
   proc gplot data=out;
      plot series * date = 1 d11 * date = 2 / overlay legend=lengend1;
   run;
   
   symbol1 i=join v=dot;
   
   proc gplot data=out;
      plot ( d10 d12 d13 ) * date;
   run;

Output 21.1.1: Plot of Original and Seasonally Adjusted Data

Output 21.1.2: Plot of D10, the Final Seasonal Factors

Output 21.1.3: Plot of D12, the Final Trend Cycle

Output 21.1.4: Plot of D13, the Final Irregular Series

Chapter Contents
Previous
Next
Top