Example 1.2: Work Breakdown Structure

Introduction to Project Management

Example 1.2: Work Breakdown Structure

A tree diagram is a useful method of visualizing the work breakdown structure of a project. For the survey project, the activities are divided into three phases. In the current example, the NETDRAW procedure is used to represent the work breakdown structure of the project. The following program saves the data in a Network data set that is input to PROC NETDRAW. The TREE option is used to draw the WBS structure in the form of a tree (Output 1.2.1).

   data wbs;
      input parent  $ 1-10
            child   $ 12-21
            style;
      datalines;
   Survey     Plan          1
   Survey     Prepare       1
   Survey     Implement     1
   Plan       Plan S.       2
   Plan       Design Q.     2
   Prepare    Hire P.       3
   Prepare    Train P.      3
   Prepare    Select H.     3
   Prepare    Print Q.      3
   Implement  Conduct S.    4
   Implement  Analyze R.    4
   Plan S.                  2
   Design Q.                2
   Hire P.                  3
   Train P.                 3
   Select H.                3
   Print Q.                 3
   Conduct S.               4
   Analyze R.               4
   ;

   goptions rotate=portrait;
   goptions hpos=50 vpos=90 border;

   title  a=90 h=1  f=swiss 'Conducting a Market Survey';
   title2 a=90 h=.8 f=swiss 'Work Breakdown Structure';
   pattern1 v=s c=black;
   pattern2 v=s c=green;
   pattern3 v=s c=blue;
   pattern4 v=s c=red;
   proc netdraw data=wbs graphics;
       actnet/act=parent font=swiss
              succ=child coutline=black tree rotatetext
              ctext=white rectilinear
              htext=3 pcompress
              ybetween=3 xbetween=50 pattern=style
              centerid;
   run;

Output 1.2.1: Work Breakdown Structure of SURVEY Project

Chapter Contents
Previous
Next
Top