Example of a Full Factorial Design in Two Blocks

Introduction to the FACTEX Procedure

Example of a Full Factorial Design in Two Blocks

See FACTEXG2 in the SAS/QC Sample Library

The previous example illustrates a complete factorial experiment involving eight runs and three factors: cutting speed (SPEED), feed rate (FEED), and tool angle (ANGLE).

Now, suppose two machines (A and B) are used to complete the experiment, with four runs being performed on each machine. To allow for the possibility that the machine affects the part finish, you should consider machine as a block factor and account for the block effect in assigning the runs to machines.

The following statements construct a blocked design:

   proc factex;
       factors speed feed angle;  /* Specify 3 factors, a 2^3 design   */
       blocks nblocks=2;          /* Specify two blocks                */
       model resolution=max;      /* Specify maximum resolution        */
       examine design;
   run;

The RESOLUTION=MAX option in the MODEL statement specifies a design with the highest resolution, that is, the best design in a general sense. Optionally, if you know the resolution of the design, you can replace RESOLUTION=MAX with RESOLUTION=r where r is the resolution number. For information on resolution, see "Resolution" .

By default, the FACTEX procedure assumes the size of the design is a full factorial and that each factor is at two levels.

After you submit the preceding statements, you will see the following messages in the SAS log:

NOTE: No design size specified.
      Default is a full replicate in 8 runs.
NOTE: Design has 8 runs in 2 blocks of size 4,
      resolution = 6.

The output is shown in Figure 14.3. Note that, by default, the name for the block variable is BLOCK and its levels are 1 and 2. Also, note that the default factor levels for a two-level design are -1 and 1.

The FACTEX Procedure

Design Points
Experiment Number	speed	feed	angle	Block
1	-1	-1	-1	1
2	-1	-1	1	2
3	-1	1	-1	2
4	-1	1	1	1
5	1	-1	-1	2
6	1	-1	1	1
7	1	1	-1	1
8	1	1	1	2

Figure 14.3: 2³ Factorial Design in Two Blocks before Decoding

You can rename the block variable and use actual levels for the block variable appropriate for your situation as follows:

   proc factex;
      factors speed feed angle;
      blocks nblocks=2;
      model resolution=max;
      output out=blocdesn              
        speed nvals=(300 500)      
        feed  nvals=(20  30 )       
        angle nvals=(6   8  )
        blockname=machine cvals=('A' 'B'); 
   run;                              
                                      
   proc print;
   run;

Figure 14.4 shows the listing of the design saved in the data set BLOCDESN.

Obs	machine	speed	feed	angle
1	A	300	20	6
2	A	300	30	8
3	A	500	20	8
4	A	500	30	6
5	B	300	20	8
6	B	300	30	6
7	B	500	20	6
8	B	500	30	8

Figure 14.4: 2³ Factorial Design in Two Blocks after Decoding

Chapter Contents
Previous
Next
Top