Example 15.4: Fold-Over Design

Details of the FACTEX Procedure

Example 15.4: Fold-Over Design

See FACTEX10 in the SAS/QC Sample Library

Folding over a fractional factorial design is a method for breaking the links between aliased effects in a design. Folding over a design means adding a new fraction identical to the original fraction except that the signs of all the factors are reversed. The new fraction is called a fold-over design. Combining a fold-over design with the original fraction converts a design of odd resolution r into a design of resolution r+1.^* For example, folding over a resolution 3 design yields a resolution 4 design. You can use the FACTEX procedure to construct the original design fraction and a DATA step to generate the fold-over design.

Consider a 1/8 fraction of a 2⁶ factorial design with factors A, B, C, D, E, and F. The following statements construct a 2^6-3_III design:

   proc factex;
      factors a b c d e f;
      size fraction=8;           /* Specify 1/8 fraction design */
      model resolution=3;        /*     of resolution 3         */
      examine aliasing;
      output out=original;
   run;

   title 'Original Design';
   proc print data=original;
   run;

The design, which is saved in the data set ORIGINAL, is displayed in Output 15.4.1.

Output 15.4.1: A 2^6-3_III Design

Original Design

Obs	a	b	c	d	e	f
1	-1	-1	-1	-1	1	1
2	-1	-1	1	1	-1	-1
3	-1	1	-1	1	-1	1
4	-1	1	1	-1	1	-1
5	1	-1	-1	1	1	-1
6	1	-1	1	-1	-1	1
7	1	1	-1	-1	-1	-1
8	1	1	1	1	1	1

Since the design is of resolution 3, the alias structure in Output 15.4.2 indicates that all the main effects are confounded with the two-factor interactions.

Output 15.4.2: Alias Structure for a 2^6-3_III Design

The FACTEX Procedure

Aliasing Structure
a = cf = de
b = ce = df
c = af = be
d = ae = bf
e = ad = bc
f = ac = bd
ab = cd = e*f

To separate the main effects and the two-factor interactions, augment the original design with a 1/8 fraction in which the signs of all the factors are reversed. The combined design (original design and fold-over design) of resolution 4 breaks the alias links between the main effects and the two-factor interactions. The fold-over design can be created using the following DATA step:

   data foldover;              /* Create the fold-over design with */
      set original;            /*    the factor signs reversed     */
      a=-a; b=-b; c=-c;
      d=-d; e=-e; f=-f;
   run;

   title 'Fold-Over Design';
   proc print data=foldover;
   run;

The fold-over design is displayed in Output 15.4.3.

Output 15.4.3: A 2^6-3_III Design with Signs Reversed

Fold-Over Design

Obs	a	b	c	d	e	f
1	1	1	1	1	-1	-1
2	1	1	-1	-1	1	1
3	1	-1	1	-1	1	-1
4	1	-1	-1	1	-1	1
5	-1	1	1	-1	-1	1
6	-1	1	-1	1	1	-1
7	-1	-1	1	1	1	1
8	-1	-1	-1	-1	-1	-1

Chapter Contents
Previous
Next
Top