Chapter Contents
Previous
Next
|
Chapter Contents |
Previous |
Next |
| BOXCHART Statement |
| See SHWBOXA in the SAS/QC Sample Library |
You can save the control limits for a box chart in a SAS data set; this enables you to apply the control limits to future data (see "Reading Preestablished Control Limits" ) or modify the limits with a DATA step program.
The following statements read measurements from the data set
TURBINE (see "Creating Box Charts from Raw Data" ) and save the control limits
displayed in Figure 32.2 in a data set named TURBLIM:
title 'Control Limits for Power Output Data';
proc shewhart data=turbine;
boxchart kwatts*day / outlimits=turblim
nochart;
run;
The OUTLIMITS= option names the data set containing the control
limits, and the NOCHART option suppresses the display of the chart.
The data set TURBLIM is listed in Figure 32.8.
The data set TURBLIM contains one observation
with the limits for process KWATTS. The variables
_LCLX_ and _UCLX_ contain the lower
and upper control limits for the means, and
the variable _MEAN_ contains the central line.
The value of _MEAN_ is an estimate of the process mean, and the value
of _STDDEV_ is an estimate of the process standard deviation 
.The value of _LIMITN_ is the nominal sample size associated
with the control limits, and the value of _SIGMAS_ is the
multiple of associated with the control limits.
The variables _VAR_ and _SUBGRP_ are bookkeeping variables
that save the process and subgroup-variable.
The variable _TYPE_ is a bookkeeping variable that indicates
whether the values of _MEAN_ and _STDDEV_ are estimates
or standard values.
The variables _LCLR_, _R_, and _UCLR_ are not used to create box charts, but they are included so that the data set TURBLIM can be used to create an R chart; see Chapter 43, "XRCHART Statement". If you specify the STDDEVIATIONS option in the BOXCHART statement, the variables _LCLS_, _S_, and _UCLS_, rather than the variables _LCLR_, _R_, and _UCLR_, are included in the OUTLIMITS= data set. These variables can be used to create an s chart; see Chapter 44, "XSCHART Statement."
If you specify CONTROLSTAT=MEDIAN to request
control limits for medians,
the variables _LCLM_ and
_UCLM_, rather than the variables _LCLX_ and _UCLX_,
are included in the OUTLIMITS= data set as demonstrated by
the following statements:
title 'Control Limits for Power Output Data';
proc shewhart data=turbine;
boxchart kwatts*day / outlimits =turblim2
controlstat=median
stddeviations
nochart;
run;
For more information, see "OUTLIMITS= Data Set" .
|
You can create an output data set containing both control limits
and summary statistics
with the OUTTABLE= option, as illustrated by
the following statements:
title 'Summary Statistics and Control Limit Information';
proc shewhart data=turbine;
boxchart kwatts*day / outtable=turbtab
nochart;
run;
The data set TURBTAB is listed in Figure 32.10.
|
This data set contains one observation for each subgroup sample. The variable _SUBMIN_ contains the subgroup minimums, and the variable _SUBQ1_ contains the first quartile for each subgroup. The variable _SUBX_ contains the subgroup means, and the variable _SUBMED_ contains the subgroup medians. The variable _SUBQ3_ contains the third quartiles, and the variable _SUBMAX_ contains the subgroup maximums. The variable _SUBN_ contains the subgroup sample sizes. The variables _LCLX_ and _UCLX_ contain the lower and upper control limits for the means. The variable _MEAN_ contains the central line. The variables _VAR_ and DAY contain the process name and values of the subgroup-variable, respectively. For more information, see "OUTTABLE= Data Set" . An OUTTABLE= data set can be read later as a TABLE= data set. For example, the following statements read TURBTAB and display a box chart (not shown here) identical to the chart in Figure 32.2:
title 'Box Chart for Power Output';
symbol v=dot;
proc shewhart table=turbtab;
boxchart kwatts*day;
label _SUBX_ = 'Average Power Output';
run;
Because the SHEWHART procedure simply displays the information in a TABLE= data set, you can use TABLE= data sets to create specialized control charts (see Chapter 49, "Specialized Control Charts").
For more information, see "TABLE= Data Set" .
|
Chapter Contents |
Previous |
Next |
 Top |
Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.