Example 34.2: Specifying Standard Values for the Process Mean and Standard Deviation

IRCHART Statement

Example 34.2: Specifying Standard Values for the Process Mean and Standard Deviation

See SHWIREX2 in the SAS/QC Sample Library

By default, the IRCHART statement estimates the process mean ( $\mu$ ) and standard deviation ( $\sigma$ )from the data, as in the previous example. However, there are applications in which known (standard) values $\mu_{0}$ and $\sigma_{0}$ are available for these parameters based on previous experience or extensive sampling.

For example, suppose that the manufacturing process described in the previous example produces engines whose weights are normally distributed with a mean of 1250 and a standard deviation of 12. The following statements create individual measurements and moving range charts based on these values:

   title 'Specifying Standard Process Mean and Standard Deviation';
   symbol v=dot c=yellow;
   proc shewhart data=engines;
      irchart weight*id /
          mu0      = 1250
          sigma0   = 12
          xsymbol  = mu0
          cframe   = vigb
          cinfill  = vlib
          cconnect = yellow
          coutfill = red;
   run;

The charts are shown in Output 34.2.1. The MU0= option and SIGMA0= option specify $\mu_{0}$ and $\sigma_{0}$ .The XSYMBOL= option specifies the label for the central line on the individual measurements chart, and the keyword MU0 requests a label indicating that the central line is based on a standard value.

Output 34.2.1: Specifying Standard Values with MU0= and SIGMA0=

You can also specify $\mu_{0}$ and $\sigma_{0}$ as the values of the variables _MEAN_ and _STDDEV_ in a LIMITS= data set. For example, the following statements create a LIMITS= data set with the standard values specified in the preceding IRCHART statement:

   data englim;
      length _var_ _subgrp_ _type_ $8;
      _var_    = 'weight';
      _subgrp_ = 'id';
      _limitn_ = 2;
      _type_   = 'STANDARD';
      _mean_   = 1250;
      _stddev_ = 12;
   run;

The variables _VAR_ and _SUBGRP_ are required, and their values must match the process and subgroup-variable, respectively, specified in the IRCHART statement. The bookkeeping variable _TYPE_ is not required, but it is recommended to indicate that the variables _MEAN_ and _STDDEV_ provide standard values rather than estimated values. See "LIMITS= Data Set" for details.

The following statements read ENGLIM as a LIMITS= data set:

   proc shewhart data=engines limits=englim;
      irchart weight*id / xsymbol=mu0;
   run;

The resulting charts (not shown here) are identical to those shown in Output 34.2.1.

Chapter Contents
Previous
Next
Top