Example 40.1: Specifying a Known Standard Deviation

SCHART Statement

Example 40.1: Specifying a Known Standard Deviation

See SHWSEX1 in the SAS/QC Sample Library

In some applications, a standard value $\sigma_{0}$ may be available for the process standard deviation $\sigma$ .This example shows how you can specify $\sigma_{0}$ to compute the control limits.

Suppose that the amount of power needed to heat water in the heating process described at "Creating Standard Deviation Charts from Raw Data" has a known standard deviation of 200. The following statements specify this known value and create an s chart, shown in Output 40.1.1, for the power output measurements in the data set TURBINE:

   title 's Chart for Power Output';
   title2 'Using Known Process Standard Deviation of 200';
    symbol v=dot c=salmon;
   proc shewhart data=turbine;
      schart kwatts*day / sigma0   = 200
                          ssymbol  = s0
                          cframe   = vligb
                          cinfill  = ywh
                          cconnect = salmon;
   run;

The SIGMA0= option specifies $\sigma_{0}$ ,and the SSYMBOL= option specifies a label for the central line indicating that the central line is computed from $\sigma_{0}$ .Since all the points lie within the limits, you can conclude that the variability of the process is stable.

Output 40.1.1: Reading in Standard Value for Process Standard Deviation

You can also specify $\sigma_{0}$ as the value of the variable _STDDEV_ in a LIMITS= data set, as illustrated by the following statements:^*

   data plimits;
      length _var_ _subgrp_ _type_ $8;
      _var_    = 'kwatts';
      _subgrp_ = 'day';
      _type_   = 'STDSIGMA';
      _limitn_ = 20;
      _stddev_ = 200;
   run;

   title 'Chart Using Known Process Standard Deviation';
   symbol v=dot;
   proc shewhart data=turbine limits=plimits;
      schart kwatts*day / ssymbol=s0;
   run;

The resulting s chart (not shown here) is identical to the one shown in Output 40.1.1. For more information, see "LIMITS= Data Set" .

Chapter Contents
Previous
Next
Top