Chapter Contents

Previous

Next

A Combined Measurement-Structural Model with Reciprocal Influence and Correlated Residuals

To illustrate a more complex model, this example uses some well-known data from Haller and Butterworth (1960). Various models and analyses of these data are given by Duncan, Haller, and Portes (1968), Jreskog and Srbom (1988), and Loehlin (1987).

The study is concerned with the career aspirations of high-school students and how these aspirations are affected by close friends. The data are collected from 442 seventeen-year-old boys in Michigan. There are 329 boys in the sample who named another boy in the sample as a best friend. The observations to be analyzed consist of the data from these 329 boys paired with the data from their best friends.

The method of data collection introduces two statistical problems. First, restricting the analysis to boys whose best friends are in the original sample causes the reduced sample to be biased. Second, since the data from a given boy may appear in two or more observations, the observations are not independent. Therefore, any statistical conclusions should be considered tentative. It is difficult to accurately assess the effects of the dependence of the observations on the analysis, but it could be argued on intuitive grounds that since each observation has data from two boys and since it seems likely that many of the boys will appear in the data set at least twice, the effective sample size may be as small as half of the reported 329 observations.

The correlation matrix is taken from Jreskog and Srbom (1988).

   title 'Peer Influences on Aspiration: Haller & Butterworth (1960)';
   data aspire(type=corr);
      _type_='corr';
      input _name_ $ riq rpa rses roa rea fiq fpa fses foa fea;
      label riq='Respondent: Intelligence'
            rpa='Respondent: Parental Aspiration'
            rses='Respondent: Family SES'
            roa='Respondent: Occupational Aspiration'
            rea='Respondent: Educational Aspiration'
            fiq='Friend: Intelligence'
            fpa='Friend: Parental Aspiration'
            fses='Friend: Family SES'
            foa='Friend: Occupational Aspiration'
            fea='Friend: Educational Aspiration';
      datalines;
   riq   1.      .      .      .      .      .       .      .      .      .
   rpa   .1839  1.      .      .      .      .       .      .      .      .
   rses  .2220  .0489  1.      .      .      .       .      .      .      .
   roa   .4105  .2137  .3240  1.      .      .       .      .      .      .
   rea   .4043  .2742  .4047  .6247  1.      .       .      .      .      .
   fiq   .3355  .0782  .2302  .2995  .2863  1.       .      .      .      .
   fpa   .1021  .1147  .0931  .0760  .0702  .2087   1.      .      .      .
   fses  .1861  .0186  .2707  .2930  .2407  .2950  -.0438  1.      .      .
   foa   .2598  .0839  .2786  .4216  .3275  .5007   .1988  .3607  1.      .
   fea   .2903  .1124  .3054  .3269  .3669  .5191   .2784  .4105  .6404  1.
   ;

The model analyzed by Jreskog and Srbom (1988) is displayed in the following path diagram:

Figure 14.17: Path Diagram: Career Aspiration, Jreskog and Srbom

Two latent variables, f_ramb and f_famb, represent the respondent's level of ambition and his best friend's level of ambition, respectively. The model states that the respondent's ambition is determined by his intelligence and socioeconomic status, his perception of his parents' aspiration for him, and his friend's socioeconomic status and ambition. It is assumed that his friend's intelligence and socioeconomic status affect the respondent's ambition only indirectly through his friend's ambition. Ambition is indexed by the manifest variables of occupational and educational aspiration, which are assumed to have uncorrelated residuals. The path coefficient from ambition to occupational aspiration is set to 1.0 to determine the scale of the ambition latent variable.

This model can be analyzed with PROC CALIS using the LINEQS statement as follows, where the names of the parameters correspond to those used by Jreskog and Srbom (1988). Since this TYPE=CORR data set does not contain an observation with _TYPE_='N' giving the sample size, it is necessary to specify the degrees of freedom (sample size minus one) with the EDF= option in the PROC CALIS statement.

   title2 'Joreskog-Sorbom (1988) analysis 1';
   proc calis data=aspire edf=328;
      lineqs    /* measurement model for aspiration */
             rea=lambda2 f_ramb + e_rea,
             roa=f_ramb + e_roa,
             fea=lambda3 f_famb + e_fea,
             foa=f_famb + e_foa,
                /* structural model of influences */
             f_ramb=gam1 rpa + gam2 riq + gam3 rses +
                gam4 fses + beta1 f_famb + d_ramb,
             f_famb=gam8 fpa + gam7 fiq + gam6 fses +
                gam5 rses + beta2 f_ramb + d_famb;
      std d_ramb=psi11,
          d_famb=psi22,
          e_rea e_roa e_fea e_foa=theta:;
      cov d_ramb d_famb=psi12,
          rpa riq rses fpa fiq fses=cov:;
   run;

Specify a name followed by a colon to represent a list of names formed by appending numbers to the specified name. For example, in the COV statement, the line

   rpa riq rses fpa fiq fses=cov:;

is equivalent to

   rpa riq rses fpa fiq fses=cov1-cov15;

The results from this analysis are as follows.

Jreskog and Srbom (1988) present more detailed results from a second analysis in which two constraints are imposed:

• The coefficents connecting the latent ambition variables are equal.
• The covariance of the disturbances of the ambition variables is zero.

This analysis can be performed by changing the names beta1 and beta2 to beta and omitting the line from the COV statement for psi12:

   title2 'Joreskog-Sorbom (1988) analysis 2';
   proc calis data=aspire edf=328;
      lineqs    /* measurement model for aspiration */
             rea=lambda2 f_ramb + e_rea,
             roa=f_ramb + e_roa,
             fea=lambda3 f_famb + e_fea,
             foa=f_famb + e_foa,
                /* structural model of influences */
             f_ramb=gam1 rpa + gam2 riq + gam3 rses +
                gam4 fses + beta f_famb + d_ramb,

             f_famb=gam8 fpa + gam7 fiq + gam6 fses +
                gam5 rses + beta f_ramb + d_famb;
      std d_ramb=psi11,
          d_famb=psi22,
          e_rea e_roa e_fea e_foa=theta:;
      cov rpa riq rses fpa fiq fses=cov:;
   run;

The results are displayed in Figure 14.19.

Loehlin (1987) points out that the models considered are unrealistic in at least two aspects. First, the variables of parental aspiration, intelligence, and socioeconomic status are assumed to be measured without error. Loehlin adds uncorrelated measurement errors to the model and assumes, for illustrative purposes, that the reliabilities of these variables are known to be 0.7, 0.8, and 0.9, respectively. In practice, these reliabilities would need to be obtained from a separate study of the same or a very similar population. If these constraints are omitted, the model is not identified. However, constraining parameters to a constant in an analysis of a correlation matrix may make the chi-square goodness-of-fit test inaccurate, so there is more reason to be skeptical of the p-values. Second, the error terms for the respondent's aspiration are assumed to be uncorrelated with the corresponding terms for his friend. Loehlin introduces a correlation between the two educational aspiration error terms and between the two occupational aspiration error terms. These additions produce the following path diagram for Loehlin's model 1.

The statements for fitting this model are as follows:

   title2 'Loehlin (1987) analysis: Model 1';
   proc calis data=aspire edf=328;
      lineqs    /* measurement model for aspiration */
             rea=lambda2 f_ramb + e_rea,
             roa=f_ramb + e_roa,
             fea=lambda3 f_famb + e_fea,
             foa=f_famb + e_foa,
             /* measurement model for intelligence and environment */
             rpa=.837 f_rpa + e_rpa,
             riq=.894 f_riq + e_riq,
             rses=.949 f_rses + e_rses,
             fpa=.837 f_fpa + e_fpa,
             fiq=.894 f_fiq + e_fiq,
             fses=.949 f_fses + e_fses,
                /* structural model of influences */
             f_ramb=gam1 f_rpa + gam2 f_riq + gam3 f_rses +
                gam4 f_fses + bet1 f_famb + d_ramb,
             f_famb=gam8 f_fpa + gam7 f_fiq + gam6 f_fses +
                gam5 f_rses + bet2 f_ramb + d_famb;
      std d_ramb=psi11,
          d_famb=psi22,
          f_rpa f_riq f_rses f_fpa f_fiq f_fses=1,
          e_rea e_roa e_fea e_foa=theta:,
          e_rpa e_riq e_rses e_fpa e_fiq e_fses=err:;
      cov d_ramb d_famb=psi12,
          e_rea e_fea=covea,
          e_roa e_foa=covoa,
          f_rpa f_riq f_rses f_fpa f_fiq f_fses=cov:;
   run;

The results are displayed in Figure 14.21.

Since it is assumed that the same model applies to all the boys in the sample, the path diagram should be symmetric with respect to the respondent and friend. In particular, the corresponding coefficients should be equal. By imposing equality constraints on the 15 pairs of corresponding coefficents, this example obtains Loehlin's model 2. The LINEQS model is as follows, where an OUTRAM= data set is created to facilitate subsequent hypothesis tests:

   title2 'Loehlin (1987) analysis: Model 2';
   proc calis data=aspire edf=328 outram=ram2;
      lineqs    /* measurement model for aspiration */
             rea=lambda f_ramb + e_rea,             /* 1 ec! */
             roa=f_ramb + e_roa,
             fea=lambda f_famb + e_fea,
             foa=f_famb + e_foa,
             /* measurement model for intelligence and environment */
             rpa=.837 f_rpa + e_rpa,
             riq=.894 f_riq + e_riq,
             rses=.949 f_rses + e_rses,
             fpa=.837 f_fpa + e_fpa,
             fiq=.894 f_fiq + e_fiq,
             fses=.949 f_fses + e_fses,
                /* structural model of influences */     /* 5 ec! */
             f_ramb=gam1 f_rpa + gam2 f_riq + gam3 f_rses +
                gam4 f_fses + beta f_famb + d_ramb,
             f_famb=gam1 f_fpa + gam2 f_fiq + gam3 f_fses +
                gam4 f_rses + beta f_ramb + d_famb;
      std d_ramb=psi,                            /* 1 ec! */
          d_famb=psi,
          f_rpa f_riq f_rses f_fpa f_fiq f_fses=1,
          e_rea e_fea=thetaea thetaea,           /* 2 ec! */
          e_roa e_foa=thetaoa thetaoa,
          e_rpa e_fpa=errpa1 errpa2,
          e_riq e_fiq=erriq1 erriq2,
          e_rses e_fses=errses1 errses2;
      cov d_ramb d_famb=psi12,
          e_rea e_fea=covea,
          e_roa e_foa = covoa,
          f_rpa f_riq f_rses=cov1-cov3,          /* 3 ec! */
          f_fpa f_fiq f_fses=cov1-cov3,
          f_rpa f_riq f_rses * f_fpa f_fiq f_fses =   /* 3 ec! */
             cov4 cov5 cov6
             cov5 cov7 cov8
             cov6 cov8 cov9;
   run;

The results are displayed in Figure 14.22.

A question of substantive interest is whether the friend's socioeconomic status (SES) has a significant direct influence on a boy's ambition. This can be addressed by omitting the paths from f_fses to f_ramb and from f_rses to f_famb designated by the parameter name gam4, yielding Loehlin's model 3:

   title2 'Loehlin (1987) analysis: Model 3';
   data ram3(type=ram);
      set ram2;
      if _name_='gam4' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;
   proc calis data=aspire edf=328 inram=ram3;
   run;

The output is displayed in Figure 14.23.

The chi-square value for testing model 3 versus model 2 is 23.0365 - 19.0697 = 3.9668 with 1 degree of freedom and a p-value of 0.0464. Although the parameter is of marginal significance, the estimate in model 2 (0.0756) is small compared to the other coefficients, and SBC indicates that model 3 is preferable to model 2.

Another important question is whether the reciprocal influences between the respondent's and friend's ambitions are needed in the model. To test whether these paths are zero, set the parameter beta for the paths linking f_ramb and f_famb to zero to obtain Loehlin's model 4:

   title2 'Loehlin (1987) analysis: Model 4';
   data ram4(type=ram);
      set ram2;
      if _name_='beta' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc calis data=aspire edf=328 inram=ram4;
   run;

The output is displayed in Figure 14.24.

The chi-square value for testing model 4 versus model 2 is 20.9981 - 19.0697 = 1.9284 with 1 degree of freedom and a p-value of 0.1649. Hence, there is little evidence of reciprocal influence.

Loehlin's model 2 has not only the direct paths connecting the latent ambition variables f_ramb and f_famb but also a covariance between the disturbance terms d_ramb and d_famb to allow for other variables omitted from the model that might jointly influence the respondent and his friend. To test the hypothesis that this covariance is zero, set the parameter psi12 to zero, yielding Loehlin's model 5:

   title2 'Loehlin (1987) analysis: Model 5';
   data ram5(type=ram);
      set ram2;
      if _name_='psi12' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc calis data=aspire edf=328 inram=ram5;
   run;

The output is displayed in Figure 14.25.

These data fail to provide evidence of direct reciprocal influence between the respondent's and friend's ambitions or of a covariance between the disturbance terms when these hypotheses are considered separately. Notice, however, that the covariance psi12 between the disturbance terms increases from -0.003344 for model 2 to 0.05479 for model 4. Before you conclude that all of these paths can be omitted from the model, it is important to test both hypotheses together by setting both beta and psi12 to zero as in Loehlin's model 7:

   title2 'Loehlin (1987) analysis: Model 7';
   data ram7(type=ram);
      set ram2;
      if _name_='psi12'|_name_='beta' then
         do;
            _name_=' ';
            _estim_=0;
         end;
   run;

   proc calis data=aspire edf=328 inram=ram7;
   run;