Chapter Contents

Previous

Next

Example 23.2: Crude Birth and Death Rates

Each cluster analysis is performed by a macro called ANALYZE. The macro takes two arguments. The first, &METHOD, specifies the value of the METHOD= option to be used in the PROC CLUSTER statement. The second, &NCL, must be specified as a list of integers, separated by blanks, indicating the number of clusters desired in each scatter plot. For example, the first invocation of ANALYZE specifies the AVERAGE method and requests plots of 3 and 8 clusters. When two-stage density linkage is used, the K= and R= options are specified as part of the first argument.

The ANALYZE macro first invokes the CLUSTER procedure with METHOD=&METHOD, where &METHOD represents the value of the first argument to ANALYZE. This part of the macro produces the PROC CLUSTER output shown.

The %DO loop processes &NCL, the list of numbers of clusters to plot. The macro variable &K is a counter that indexes the numbers within &NCL. The %SCAN function picks out the &Kth number in &NCL, which is then assigned to the macro variable &N. When &K exceeds the number of numbers in &NCL, %SCAN returns a null string. Thus, the %DO loop executes while &N is not equal to a null string. In the %WHILE condition, a null string is indicated by the absence of any nonblank characters between the comparison operator (NE) and the right parenthesis that terminates the condition.

Within the %DO loop, the TREE procedure creates an output data set containing &N clusters. The GPLOT procedure then produces a scatter plot in which each observation is identified by the number of the cluster to which it belongs. The TITLE2 statement uses double quotes so that &N and &METHOD can be used within the title. At the end of the loop, &K is incremented by 1, and the next number is extracted from &NCL by %SCAN.

For this example, plots are obtained only for average linkage. To generate plots for other methods, follow the example shown in the first macro call. The following statements produce Output 23.2.1 through Output 23.2.7.

   title 'Cluster Analysis of Birth and Death Rates';

   %macro analyze(method,ncl);
   proc cluster data=poverty outtree=tree method=&method p=15 ccc pseudo;
      var birth death;
      title2;
   run;
   %let k=1;
   %let n=%scan(&ncl,&k);
   %do %while(&n NE);
      proc tree data=tree noprint out=out ncl=&n;
         copy birth death;
      run;
      legend1 frame cframe=ligr cborder=black 
              position=center value=(justify=center);
      axis1 label=(angle=90 rotate=0) minor=none;
      axis2 minor=none;
      proc gplot;
         plot death*birth=cluster / 
         frame cframe=ligr legend=legend1 vaxis=axis1 haxis=axis2;
         title2 "Plot of &n Clusters from METHOD=&METHOD";
      run;
      %let k=%eval(&k+1);
      %let n=%scan(&ncl,&k);
   %end;
   %mend;

   %analyze(average,3 8)
   %analyze(complete,3)
   %analyze(single,7 10)
   %analyze(two k=10,3)
   %analyze(two k=18,2)

For average linkage, the CCC has peaks at 3, 8, 10, and 12 clusters, but the 3-cluster peak is lower than the 8-cluster peak. The pseudo F statistic has peaks at 3, 8, and 12 clusters. The pseudo t² statistic drops sharply at 3 clusters, continues to fall at 4 clusters, and has a particularly low value at 12 clusters. However, there are not enough data to seriously consider as many as 12 clusters. Scatter plots are given for 3 and 8 clusters. The results are shown in Output 23.2.1 through Output 23.2.3. In Output 23.2.3, the eighth cluster consists of the two outlying observations, Mexico and Korea.

The scatter plot for 3 clusters is shown. The results are shown in Output 23.2.4.

The CCC and pseudo F statistics are not appropriate for use with single linkage because of the method's tendency to chop off tails of distributions. The pseudo t² statistic can be used by looking for large values and taking the number of clusters to be one greater than the level at which the large pseudo t² value is displayed. For these data, there are large values at levels 6 and 9, suggesting 7 or 10 clusters.

The scatter plots for 7 and 10 clusters are shown. The results are shown in Output 23.2.5.

For kth-nearest-neighbor density linkage, the number of modes as a function of k is as follows (not all of these analyses are shown):

Thus, there is strong evidence of 3 modes and an indication of the possibility of 2 modes. Uniform-kernel density linkage gives similar results. For K=10 (10th-nearest-neighbor density linkage), the scatter plot for 3 clusters is shown; and for K=18, the scatter plot for 2 clusters is shown. The results are shown in Output 23.2.6.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.