Example 9.2: Displaying a Lognormal Reference Line

PROBPLOT Statement

Example 9.2: Displaying a Lognormal Reference Line

See CAPPROB3 in the SAS/QC Sample Library

This example is a continuation of "Creating Lognormal Probability Plots". Figure 9.4 shows that a lognormal distribution with shape parameter $\sigma=0.5$ is a good fit for the distribution of DIAMETER in the data set MEASURES.

The lognormal distribution involves two other parameters: a threshold parameter $\theta$ and a scale parameter $\zeta$ .See Table 9.13 for the equation of the lognormal density function. The following statements illustrate how you can request a diagonal distribution reference line whose slope and intercept are determined by estimates of $\theta$ and $\zeta$ .

   symbol v=dot height=3.5pct;
   legend2 frame cframe=ligr cborder=black position=center;
   title 'Lognormal Probability Plot for Diameters';

   proc capability data=measures noprint;
      probplot diameter / lognormal(sigma=0.5 theta=est
                                    zeta=est color=yellow w=2)
                          square
                          pctlminor
                          HREF=95
                          lHREF=2
                          hreflabel = '95%'
                          vref      = 5.8 to 6.0 by 0.1
                          lvref     = 3
                          cframe    = ligr
                          legend    = legend2
                          cHREF=red
                          cvref     = blue;
   run;

The plot is shown in Output 9.2.1.

Output 9.2.1: Lognormal Reference Line

The close agreement between the diagonal reference line and the point pattern indicates that the specific lognormal distribution with $\hat{\sigma}=0.5$ , $\hat{\theta}=5.004$ , and $\hat{\zeta}=-1.003$ is a good fit for the diameter measurements. Specifying HREF=95 adds a reference line indicating the 95^th percentile of the lognormal distribution. The LHREF=and HREFLABEL= options specify the line type and a label for this line. The PCTLMINOR option displays minor tick marks on the percentile axis. The VREF= option adds reference lines indicating diameter values of 5.8, 5.9, and 6.0, and the LVREF= option specifies their line type.

Based on the intersection of the diagonal reference line with the HREF=line, the estimated 95^th percentile of the diameter distribution is 5.85 mm.

Note that you could also construct a similar plot in which all three parameters are estimated by substituting SIGMA=EST for SIGMA=0.5 in the preceding statements.

Chapter Contents
Previous
Next
Top