Chapter Contents

Previous

Next

Example 41.5: Random Coefficients

The SAS code is as follows:

   data rc;
      input Batch Month @@;
      Monthc = Month;
      do i = 1 to 6;
         input Y @@;
         output;
      end;
      datalines;
   1   0  101.2 103.3 103.3 102.1 104.4 102.4
   1   1   98.8  99.4  99.7  99.5    .     .
   1   3   98.4  99.0  97.3  99.8    .     .
   1   6  101.5 100.2 101.7 102.7    .     .
   1   9   96.3  97.2  97.2  96.3    .     .
   1  12   97.3  97.9  96.8  97.7  97.7  96.7
   2   0  102.6 102.7 102.4 102.1 102.9 102.6
   2   1   99.1  99.0  99.9 100.6    .     .
   2   3  105.7 103.3 103.4 104.0    .     .
   2   6  101.3 101.5 100.9 101.4    .     .
   2   9   94.1  96.5  97.2 95.6     .     .
   2  12   93.1  92.8  95.4 92.2   92.2  93.0
   3   0  105.1 103.9 106.1 104.1 103.7 104.6
   3   1  102.2 102.0 100.8  99.8    .     .
   3   3  101.2 101.8 100.8 102.6    .     .
   3   6  101.1 102.0 100.1 100.2    .     .
   3   9  100.9  99.5 102.2 100.8    .     .
   3  12   97.8  98.3  96.9  98.4  96.9  96.5
   ;

   proc mixed data=rc;
      class Batch;
      model Y = Month / s;
      random Int Month / type=un sub=Batch s;
   run;

In the DATA step, Monthc is created as a duplicate of Month in order to allow both a continuous and classification version of the same variable. The variable Monthc is used in a subsequent analysis.

In the PROC MIXED code, Batch is listed as the only classification variable. The fixed effect Month in the MODEL statement is not declared a classification variable; thus it models a linear trend in time. An intercept is included as a fixed effect by default, and the S option requests that the fixed-effects parameter estimates be produced.

The two RANDOM effects are Int and Month, modeling random intercepts and slopes, respectively. Note that Intercept and Month are used as both fixed and random effects. The TYPE=UN option in the RANDOM statement specifies an unstructured covariance matrix for the random intercept and slope effects. In mixed model notation, G is block diagonal with unstructured 2×2 blocks. Each block corresponds to a different level of Batch, which is the SUBJECT= effect. The unstructured type provides a mechanism for estimating the correlation between the random coefficients. The S option requests the production of the random-effects parameter estimates.

The results from this analysis are shown in Output 41.5.1.

It is also possible to fit a random coefficients model with error terms that follow a nested structure (Fuller and Battese 1973). The following SAS code represents one way of doing this:

   proc mixed data=rc;
      class Batch Monthc;
      model Y = Month / s;
      random Int Month Monthc / sub=Batch s;
   run;

The results from this analysis are shown in Output 41.5.2.

The estimate for the Intercept variance component equals 0. This occurs frequently in practice and indicates that the restricted likelihood is maximized by setting this variance component equal to 0. Whenever a zero variance component estimate occurs, the following note appears in the SAS log:

   NOTE: Estimated G matrix is not positive definite.

The remaining variance component estimates are positive, and the estimate corresponding to the nested errors (MONTHC) is much larger than the other two.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.