Chapter Contents

Previous

Next

Example 41.6: Line-Source Sprinkler Irrigation

These data appear in Hanks et al. (1980), Johnson, Chaudhuri, and Kanemasu (1983), and Stroup (1989b). Three cultivars (Cult) of winter wheat are randomly assigned to rectangular plots within each of three blocks (Block). The nine plots are located side-by-side, and a line-source sprinkler is placed through the middle. Each plot is subdivided into twelve subplots, six to the north of the line-source, six to the south (Dir). The two plots closest to the line-source represent the maximum irrigation level (Irrig=6), the two next-closest plots represent the next-highest level (Irrig=5), and so forth.

This example is a case where both G and R can be modeled. One of Stroup's models specifies a diagonal G containing the variance components for Block, Block*Dir, and Block*Irrig, and a Toeplitz R with four bands. The SAS code to fit this model and carry out some further analyses follows.

Caution: This analysis may require considerable CPU time.

   data line;
      length Cult$ 8;
      input Block Cult$ @;
      row = _n_;
      do Sbplt=1 to 12;
        if Sbplt le 6 then do;
          Irrig = Sbplt;
          Dir = 'North';
        end;
        else do;
          Irrig = 13 - Sbplt;
          Dir = 'South';
        end;
        input Y @; output;
      end;
      datalines;
   1 Luke     2.4 2.7 5.6 7.5 7.9 7.1 6.1 7.3 7.4 6.7 3.8 1.8
   1 Nugaines 2.2 2.2 4.3 6.3 7.9 7.1 6.2 5.3 5.3 5.2 5.4 2.9
   1 Bridger  2.9 3.2 5.1 6.9 6.1 7.5 5.6 6.5 6.6 5.3 4.1 3.1
   2 Nugaines 2.4 2.2 4.0 5.8 6.1 6.2 7.0 6.4 6.7 6.4 3.7 2.2
   2 Bridger  2.6 3.1 5.7 6.4 7.7 6.8 6.3 6.2 6.6 6.5 4.2 2.7
   2 Luke     2.2 2.7 4.3 6.9 6.8 8.0 6.5 7.3 5.9 6.6 3.0 2.0
   3 Nugaines 1.8 1.9 3.7 4.9 5.4 5.1 5.7 5.0 5.6 5.1 4.2 2.2
   3 Luke     2.1 2.3 3.7 5.8 6.3 6.3 6.5 5.7 5.8 4.5 2.7 2.3
   3 Bridger  2.7 2.8 4.0 5.0 5.2 5.2 5.9 6.1 6.0 4.3 3.1 3.1
   ;

   proc mixed;
      class Block Cult Dir Irrig;
      model Y = Cult|Dir|Irrig@2;
      random Block Block*Dir Block*Irrig;
      repeated / type=toep(4) sub=Block*Cult r;
      lsmeans Cult|Irrig;
      estimate 'Bridger vs Luke' Cult 1 -1 0;
      estimate 'Linear Irrig' Irrig -5 -3 -1 1 3 5;
      estimate 'B vs L x Linear Irrig' Cult*Irrig
               -5 -3 -1 1 3 5 5 3 1 -1 -3 -5;
   run;

The preceding code uses the bar operator ( | ) and the at sign ( @ ) to specify all two-factor interactions between Cult, Dir, and Irrig as fixed effects.

The RANDOM statement sets up the Z and G matrices corresponding to the random effects Block, Block* Dir, and Block*Irrig.

In the REPEATED statement, the TYPE=TOEP(4) option sets up the blocks of the R matrix to be Toeplitz with four bands below and including the main diagonal. The subject effect is Block( Cult), and it produces nine 12×12 blocks. The R option requests that the first block of R be displayed.

Least-squares means (LSMEANS) are requested for Cult, Irrig, and Cult*Irrig, and a few ESTIMATE statements are specified to illustrate some linear combinations of the fixed effects.

The results from this analysis are shown in Output 41.6.1.

The first block of the estimated R matrix has the TOEP(4) structure, and the observations that are three plots apart exhibit a negative correlation.

An interesting exercise is to try fitting other variance-covariance models to these data and comparing them to this one using likelihood ratio tests, Akaike's Information Criterion, or Schwarz's Bayesian Information Criterion. In particular, some spatial models are worth investigating (Marx and Thompson 1987; Zimmerman and Harville 1991). The following is one example of spatial model code.

   proc mixed;
      class Block Cult Dir Irrig;
      model Y = Cult|Dir|Irrig@2;
      repeated / type=sp(pow)(Row Sbplt)
         sub=intercept;
   run;

The TYPE=SP(POW)(ROW SBPLT) option in the REPEATED statement requests the spatial power structure, with the two defining coordinate variables being Row and Sbplt. The SUB=INTERCEPT option indicates that the entire data set is to be considered as one subject, thereby modeling R as a dense 108×108 covariance matrix. Refer to Wolfinger (1993) for further discussion of this example and additional analyses.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.