Chapter Contents

Previous

Next

Introductory Examples

The following introductory examples illustrate how to get started using the NLP procedure.

An Unconstrained Problem

The following statements can be used to solve this problem:

   proc nlp;
      min f;
      decvar x1 x2;
      f1 = 10 * (x2 - x1 * x1);
      f2 = 1 - x1;
      f  = .5 * (f1 * f1 + f2 * f2);
   run;

The MIN statement identifies the symbol f that characterizes the objective function in terms of f1 and f2, and the DECVAR statement names the decision variables X1 and X2. Because there is no explicit optimizing algorithm option specified (TECH=) PROC NLP uses the Newton-Raphson method with ridging, the default algorithm when there are no constraints.

A better way to solve this problem is to take advantage of the fact that f is a sum of squares of f1 and f2 and to treat it as a least-squares problem. Using the LSQ statement instead of the MIN statement tells the procedure that this is a least-squares problem, which results in the use of one of the specialized algorithms for solving least-squares problems (for example Levenberg-Marquardt).

   proc nlp;
      lsq f1 f2;
      decvar x1 x2;
      f1 = 10 * (x2 - x1 * x1);
      f2 = 1 - x1;
   run;

The LSQ statement results in the minimization of a function that is the sum of squares of functions that appear in the LSQ statement. The least-squares specification is preferred because it enabless the procedure to exploit the structure in the problem for numeric stability and performance.

PROC NLP displays the iteration history and the solution to this least-squares problem as shown in Figure 5.1. It shows that the solution has x₁=1 and x₂=1. As expected in an unconstrained problem, the gradient at the solution is very close to 0.

Boundary Constraints on the Decision Variables

   proc nlp;
      lsq f1 f2;
      decvar x1 x2;
      bounds x1 - x2 <= .5;
      f1 = 10 * (x2 - x1 * x1);
      f2 = 1 - x1;
   run;

The solution in Figure 5.2 shows that the decision variables meet the constraint bounds.

Linear Constraints on the Decision Variables

   proc nlp;
      lsq f1 f2;
      decvar x1 x2;
      bounds x1 - x2 <= .5;
      lincon x1 + x2 <= .6;
      f1 = 10 * (x2 - x1 * x1);
      f2 = 1 - x1;
   run;

The output in Figure 5.3 displays the iteration history and the convergence criterion.

Figure 5.4 shows that the solution satisfies the linear constraint. Note that the procedure displays the active constraints (the constraints that are tight) at optimality.

Nonlinear Constraints on the Decision Variables

   proc nlp tech=QUANEW;
      min f;
      decvar x1 x2;
      bounds x1 - x2 <= .5;
      lincon x1 + x2 <= .6;
      nlincon c1 >= 0;

      c1 = x1 * x1 - 2 * x2;
 
      f1 = 10 * (x2 - x1 * x1);
      f2 = 1 - x1;

      f = .5 * (f1 * f1 + f2 * f2);
   run;

Not all of the optimization methods support nonlinear constraints. In particular the Levenberg-Marquardt method, the default for LSQ, does not support nonlinear constraints. (For more information about the particular algorithms, see the section "Optimization Algorithms".) The Quasi-Newton method is the prime choice for solving nonlinear programs with nonlinear constraints. The option TECH=QUANEW in the PROC NLP statement causes the Quasi-Newton method to be used.

Figure 5.5 shows the iteration history.

Figure 5.6 shows the solution to this problem.

A Simple Maximum Likelihood Example

The maximum likelihood estimates of the parameters and is the solution to

In the following DATA step, values for x are input into SAS data set X; this data set provides the values of x_i.

    data x; 
      input x @@; 
    datalines;
    1 3 4 5 7
    ;

In the following statements, the DATA=X specification drives the building of the objective function. When each observation in the DATA=X data set is read, a new term using the value of x_i is added to the objective function LOGLIK specified in the MAX statement.

    proc nlp data=x vardef=n covariance=h pcov phes;
      profile mean sigma / alpha=.5 .1 .05 .01;
      max loglik;
      parms mean=0, sigma=1;
      bounds sigma > 1e-12;
      loglik=-0.5*((x-mean)/sigma)**2-log(sigma);
   run;

After a few iterations of the default Newton-Raphson optimization algorithm, PROC NLP procedure produces the following results.

Figure 5.7: Maximum Likelihood Estimates

In unconstrained maximization, the gradient (that is, the vector of first derivatives) at the solution must be very close to zero and the Hessian matrix at the solution (that is, the matrix of second derivatives) must have nonpositive eigenvalues.

Under reasonable assumptions, the approximate standard errors of the estimates are the square roots of the diagonal elements of the covariance matrix of the parameter estimates which (because of the COV=H specification) is the same as the inverse of the Hessian matrix:

The PROFILE statement computes the values of the profile likelihood confidence limits on SIGMA and the MEAN as specified.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.