Chapter Contents
Previous
Next
|
Chapter Contents |
Previous |
Next |
| The CALIS Procedure |
A second-order confirmatory factor analysis model is applied to a correlation matrix of Thurstone reported by McDonald (1985). Using the LINEQS statement, the three-term second-order factor analysis model is specified in equations notation. The first-order loadings for the three factors, F1, F2, and F3, each refer to three variables, X1-X3, X4-X6, and X7-X9. One second-order factor, F4, reflects the correlations among the three first-order factors. The second-order factor correlation matrix P is defined as a 1 ×1 identity matrix. Choosing the second-order uniqueness matrix U2 as a diagonal matrix with parameters U21-U23 gives an unidentified model. To compute identified maximum likelihood estimates, the matrix U2 is defined as a 3 ×3 identity matrix. The following code generates results that are partially displayed in Output 19.3.1.
data Thurst(TYPE=CORR);
Title "Example of THURSTONE resp. McDONALD (1985, p.57, p.105)";
_TYPE_ = 'CORR'; Input _NAME_ $ Obs1-Obs9;
Label Obs1='Sentences' Obs2='Vocabulary' Obs3='Sentence Completion'
Obs4='First Letters' Obs5='Four-letter Words' Obs6='Suffices'
Obs7='Letter series' Obs8='Pedigrees' Obs9='Letter Grouping';
datalines;
Obs1 1. . . . . . . . .
Obs2 .828 1. . . . . . . .
Obs3 .776 .779 1. . . . . . .
Obs4 .439 .493 .460 1. . . . . .
Obs5 .432 .464 .425 .674 1. . . . .
Obs6 .447 .489 .443 .590 .541 1. . . .
Obs7 .447 .432 .401 .381 .402 .288 1. . .
Obs8 .541 .537 .534 .350 .367 .320 .555 1. .
Obs9 .380 .358 .359 .424 .446 .325 .598 .452 1.
;
proc calis data=Thurst method=max edf=212 pestim se;
Title2 "Identified Second Order Confirmatory Factor Analysis";
Title3 "C = F1 * F2 * P * F2' * F1' + F1 * U2 * F1' + U1, With P=U2=Ide";
Lineqs
Obs1 = X1 F1 + E1,
Obs2 = X2 F1 + E2,
Obs3 = X3 F1 + E3,
Obs4 = X4 F2 + E4,
Obs5 = X5 F2 + E5,
Obs6 = X6 F2 + E6,
Obs7 = X7 F3 + E7,
Obs8 = X8 F3 + E8,
Obs9 = X9 F3 + E9,
F1 = X10 F4 + E10,
F2 = X11 F4 + E11,
F3 = X12 F4 + E12;
Std
F4 = 1. ,
E1-E9 = U11-U19 ,
E10-E12 = 3 * 1.;
Bounds
0. <= U11-U19;
run;
Output 19.3.1: Second-Order Confirmatory Factor Analysis
|
|
| ||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
|
| |||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||||
Std
F4 = 1. ,
E1-E9 = U11-U19 ,
E10-E12 = U21-U23 ;
Bounds
0. <= U11-U19,
0. <= U21-U23;
The unidentified model is indicated in the output by an analysis of the linear dependencies in the approximate Hessian matrix (not shown). Because the information matrix is singular, standard errors are computed based on a Moore-Penrose inverse. The results computed by PROC CALIS differ from those reported by McDonald (1985). In the case of an unidentified model, the parameter estimates are not unique.
To specify the identified model using the COSAN model statement, you can use the following statements:
Title2 "Identified Second Order Confirmatory Factor Analysis Using COSAN";
Title3 "C = F1*F2*P*F2'*F1' + F1*U2*F1' + U1, With P=U2=Ide";
proc calis data=Thurst method=max edf=212 pestim se;
Cosan F1(3) * F2(1) * P(1,Ide) + F1(3) * U2(3,Ide) + U1(9,Dia);
Matrix F1
[ ,1] = X1-X3,
[ ,2] = 3 * 0. X4-X6,
[ ,3] = 6 * 0. X7-X9;
Matrix F2
[ ,1] = X10-X12;
Matrix U1
[1,1] = U11-U19;
Bounds
0. <= U11-U19;
run;
Because PROC CALIS cannot compute initial estimates for a model specified by the general COSAN statement, this analysis may require more iterations than one using the LINEQS statement, depending on the precision of the processor.
|
Chapter Contents |
Previous |
Next |
 Top |
Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.