Chapter Contents

Previous

Next

Output Data Sets

OUTEST= Data Set

• the BY variables, if any
• _MODEL_, a character variable containing the label of the corresponding MODEL statement, or MODELn if no label is specified, where n is 1 for the first MODEL statement, 2 for the second model statement, and so on
• _TYPE_, a character variable with the value 'PARMS' for every observation
• _DEPVAR_, the name of the dependent variable
• _RMSE_, the root mean squared error or the estimate of the standard deviation of the error term
• Intercept, the estimated intercept, unless the NOINT option is specified
• all the variables listed in any MODEL or VAR statement. Values of these variables are the estimated regression coefficients for the model. A variable that does not appear in the model corresponding to a given observation has a missing value in that observation. The dependent variable in each model is given a value of -1.

If you specify the COVOUT option, the covariance matrix of the estimates is output after the estimates; the _TYPE_ variable is set to the value 'COV' and the names of the rows are identified by the 8-byte character variable, _NAME_.

If you specify the TABLEOUT option, the following statistics listed by _TYPE_ are added after the estimates:

• STDERR, the standard error of the estimate
• T, the t statistic for testing if the estimate is zero
• PVALUE, the associated p-value
• LnB, the lower confidence for the estimate, where n is the nearest integer to and defaults to 0.05 or is set using the ALPHA= option in the PROC REG or MODEL statement
• UnB, the upper confidence for the estimate

Specifying the option ADJRSQ, AIC, BIC, CP, EDF, GMSEP, JP, MSE, PC, RSQUARE, SBC, SP, or SSE in the PROC REG or MODEL statement automatically outputs these statistics and the model R² for each model selected, regardless of the model selection method. Additional variables, in order of occurrence, are as follows:

• _IN_, the number of regressors in the model not including the intercept
• _P_, the number of parameters in the model including the intercept, if any
• _EDF_, the error degrees of freedom
• _SSE_, the error sum of squares, if the SSE option is specified
• _MSE_, the mean squared error, if the MSE option is specified
• _RSQ_, the R² statistic
• _ADJRSQ_, the adjusted R², if the ADJRSQ option is specified
• _CP_, the C_p statistic, if the CP option is specified
• _SP_, the S_p statistic, if the SP option is specified
• _JP_, the J_p statistic, if the JP option is specified
• _PC_, the PC statistic, if the PC option is specified
• _GMSEP_, the GMSEP statistic, if the GMSEP option is specified
• _AIC_, the AIC statistic, if the AIC option is specified
• _BIC_, the BIC statistic, if the BIC option is specified
• _SBC_, the SBC statistic, if the SBC option is specified

The following is an example with a display of the OUTEST= data set. This example uses the population data given in the section "Polynomial Regression". Figure 55.15 through Figure 55.17 show the regression equations and the resulting OUTEST= data set.

   proc reg data=USPopulation outest=est;
      m1: model Population=Year;
      m2: model Population=Year YearSq;
   proc print data=est;
   run;

The following modification of the previous example uses the TABLEOUT and ALPHA= options to obtain additional information in the OUTEST= data set:

 
   proc reg data=USPopulation outest=est tableout alpha=0.1;
      m1: model Population=Year/noprint;
      m2: model Population=Year YearSq/noprint;
   proc print data=est;
   run;

Notice that the TABLEOUT option causes standard errors, t statistics, p-values, and confidence limits for the estimates to be added to the OUTEST= data set. Also note that the ALPHA= option is used to set the confidence level at 90%. The OUTEST= data set follows.

A slightly different OUTEST= data set is created when you use the RSQUARE selection method. This example requests only the "best" model for each subset size but asks for a variety of model selection statistics, as well as the estimated regression coefficients. An OUTEST= data set is created and displayed. See Figure 55.19 and Figure 55.20 for results.

   proc reg data=fitness outest=est;
      model Oxygen=Age Weight RunTime RunPulse RestPulse MaxPulse
            / selection=rsquare mse jp gmsep cp aic bic sbc b best=1;
   proc print data=est;
   run;

OUTSSCP= Data Sets

The SSCP data set is used when a large number of observations are explored in many different runs. The SSCP data set can be saved and used for subsequent runs, which are much less expensive since PROC REG never reads the original data again. If you run PROC REG once to create only a SSCP data set, you should list all the variables that you may need in a VAR statement or include all the variables that you may need in a MODEL statement.

The following example uses the fitness data from Example 55.1 to produce an output data set with the OUTSSCP= option. The resulting output is shown in Figure 55.21.

   proc reg data=fitness outsscp=sscp;
      var Oxygen RunTime Age Weight RestPulse RunPulse MaxPulse;
   proc print data=sscp;
   run;

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.