Chapter Contents

Previous

Next

Example 8.5: Money Demand Model

The following example estimates the log-log money demand equation using the maximum likelihood method. The money demand model contains four explanatory variables. The lagged nominal money stock M1 is divided by the current price level GDF to calculate a new variable M1CP since the money stock is assumed to follow the partial adjustment process. The variable M1CP is then used to estimate the coefficient of adjustment. All variables are transformed using the natural logarithm with a DATA step. Refer to Balke and Gordon (1986) for data description.

The first eight observations are printed using the PRINT procedure and are shown in Output 8.5.1. Note that the first observation of the variables M1CP and INFR are missing. Therefore, the money demand equation is estimated for the period 1968:2 to 1983:4 since PROC AUTOREG ignores the first missing observation.

   data money;
      date = intnx( 'qtr', '01jan1968'd, _n_-1 );
      format date yyqc6.;
      input m1 gnp gdf ycb @@;
      m = log( 100 * m1 / gdf );
      m1cp = log( 100 * lag(m1) / gdf );
      y = log( gnp );
      intr = log( ycb );
      infr = 100 * log( gdf / lag(gdf) );
      label m    = 'Real Money Stock (M1)'
            m1cp = 'Lagged M1/Current GDF'
            y    = 'Real GNP'
            intr = 'Yield on Corporate Bonds'
            infr = 'Rate of Prices Changes';
   datalines;
   ;

   title 'Partial Adjustment Money Demand Equation';
   title2 'Quarterly Data - 1968:2 to 1983:4';
   
   proc autoreg data=money outest=est covout;
      model m = m1cp y intr infr / dw=4 dwprob;
   run;

   proc autoreg data=money;
      model m = m1cp y intr infr / nlag=1 method=ml maxit=50;
      output out=a p=p pm=pm r=r rm=rm ucl=ucl lcl=lcl
                   uclm=uclm lclm=lclm;
   run;
   
   proc print data=a(obs=8);
      var p pm r rm ucl lcl uclm lclm;
   run;

A difference is shown between the OLS estimates in Output 8.5.2 and the AR(1)-ML estimates in Output 8.5.3. The estimated autocorrelation coefficient is significantly negative (-0.88345). Note that the negative coefficient of A(1) should be interpreted as a positive autocorrelation.

Two predicted values are produced dash predicted values computed for the structural model and predicted values computed for the full model. The full model includes both the structural and error-process parts. The predicted values and residuals are stored in the output data set A, as are the upper and lower 95% confidence limits for the predicted values. Part of the data set A is shown in Output 8.5.4. The first observation is missing since the explanatory variables, M1CP and INFR, are missing for the corresponding observation.

Chapter Contents

Previous

Next

Top

Copyright © 1999 by SAS Institute Inc., Cary, NC, USA. All rights reserved.